342 lines
14 KiB
Plaintext
342 lines
14 KiB
Plaintext
-> POST_PERFORM_MOODTATTOOS
|
|
|
|
=== POST_PERFORM_MOODTATTOOS ===
|
|
#Environment: van_exterior
|
|
|
|
#AddChar: Singer, Pose: neutral
|
|
#AddChar: Guitarist, Pose: neutral
|
|
#AddChar: Bassist, Pose: neutral
|
|
#AddChar: Keyboardist, Pose: neutral
|
|
#AddChar: Drummer, Pose: neutral
|
|
|
|
//MK: I'm not convinced that Singer would speak first if they'd switched lyrics, I gave this to Akai. If we're saying that the performance always goes well in the room, Singer could start this because they want to say "see? It worked!" So, I gave this to Akai for the moment.
|
|
|
|
DRUMMER: LET'S GET WASTED!
|
|
SINGER: I think Akai means "great first show!"
|
|
|
|
{
|
|
- (song_stance_L1 == "Pro-Tattoo") && (vocals_moodtattoo == "Anti-Tattoo"):
|
|
KEYBOARDIST: I'm glad one of us thinks so. I'm so sad. How you could sing those lyrics? We were supposed to be pro-tattoo.
|
|
-> DISSENT_STANCE_ANTI
|
|
- (song_stance_L1 == "Anti-Tattoo") && (vocals_moodtattoo == "Pro-Tattoo"):
|
|
GUITARIST: Don't even! If you're just going to sing whatever you want, I should play whatever I want!
|
|
-> DISSENT_STANCE_PRO
|
|
- else:
|
|
DRUMMER: I would never say you were great. But the crowd did love it.
|
|
~ band_unity++
|
|
{MOODTATTOOS_JAM.DISSENTER_SINGER: -> DISSENTER_STANCE_SWITCH | -> REVIEWS}
|
|
}
|
|
|
|
= DISSENTER_STANCE_SWITCH
|
|
BASSIST: Hey, {name_singer}. Thanks for doing what we agreed on.
|
|
-> REVIEWS
|
|
|
|
= DISSENT_STANCE_ANTI
|
|
~ band_unity-- //Dissent automatically knocks down band unity. Only the players' choices can bring it back up, or knock it down farther.
|
|
BASSIST: Gotta say, {name_singer}... I like the whole anti-corporate angle.
|
|
BASSIST: But I'm not into you just going rogue. At all.
|
|
|
|
+ SINGER: I'm good with my choice. #PRIVATE
|
|
SINGER: I have to be true to my conscience. No matter what.
|
|
+ SINGER: That was selfish. I shouldn't have done that. #PRIVATE
|
|
SINGER: I let my own feelings get the better of me. I'm sorry.
|
|
SINGER: We agreed on the song's direction... and I ignored that.
|
|
-
|
|
~ temp mood = 0
|
|
|
|
+ BASSIST: I can accept that. #PRIVATE
|
|
BASSIST: Okay. It's in the past. I hope it stays there.
|
|
~ mood++
|
|
+ BASSIST: That's just noise, and I don't like it. #PRIVATE
|
|
BASSIST: If you pull this shit again, I'm gone. //MK: not sure if we can do this, but it makes sense for the character in this case. WhaleSong works regardless of stance. This song has two different messages.
|
|
~ mood--
|
|
-
|
|
|
|
GUITARIST: Yeah... well...
|
|
|
|
+ GUITARIST: Glad this went my way. But, I can't admit that... #private
|
|
GUITARIST: I should be happy about this, but I'm not. This is not cool.
|
|
~ mood++
|
|
+ (PERSONAL) GUITARIST: I'm pissed off. This is personal. #PRIVATE
|
|
GUITARIST: I guess all these votes are bullshit. We can do whatever we want.
|
|
GUITARIST: I'll remember that.
|
|
~ its_personal = "true"
|
|
~ mood--
|
|
-
|
|
|
|
{
|
|
- mood == 0: //Bassist and Guitarist had opposite responses and cancelled each other out
|
|
KEYBOARDIST: I don't like this. Can it just be fine and we can move on? I say yes.
|
|
~ band_unity +=1
|
|
- mood == 2: //mood is positive
|
|
KEYBOARDIST: If you're all okay with this, so am I.
|
|
~ band_unity +=2
|
|
- else: //mood is negative
|
|
KEYBOARDIST: You can sing for the band, {name_singer}, but you don't speak for us.
|
|
~ band_unity -=2
|
|
}
|
|
|
|
-> BAND_UNITY_CHECK
|
|
|
|
= DISSENT_STANCE_PRO
|
|
~ band_unity--
|
|
//MK: I made these a bit less certain, because S didn't want to be pro-tattoo
|
|
|
|
+ SINGER: This was the only positive option. #PRIVATE
|
|
SINGER: Anti-tattoo messages just felt too negative. That's not us.
|
|
+ SINGER: I feel awful. I can't believe I did that. #PRIVATE
|
|
SINGER: I don't know what I was thinking. I guess I was afraid. I'm sorry.
|
|
-
|
|
~ temp mood = 0
|
|
BASSIST: This isn't what we planned...
|
|
|
|
+ BASSIST: But it's only one song... #PRIVATE
|
|
BASSIST: It's our first song. The crowd liked it. We'll outlive it.
|
|
~ mood++
|
|
+ BASSIST: And on-stage surprises suck. #PRIVATE
|
|
BASSIST: {name_guitarist} is right. We were surprised. You're lucky we kept playing at all.
|
|
~ mood--
|
|
-
|
|
|
|
+ GUITARIST: I'll be the bigger person, here. #PRIVATE
|
|
GUITARIST: One of us has to rise above our petty personal gripes. I'll do it.
|
|
~ mood++
|
|
+ (PERSONAL) GUITARIST: I didn't make this personal, but it is. #PRIVATE
|
|
GUITARIST: We can do whatever we want on stage. {name_singer} showed us that tonight.
|
|
~ its_personal = "true"
|
|
~ mood--
|
|
-
|
|
|
|
//HJ: This is the Pro Tattoo stance, so Keys would have something to say since they're pro mood tattoo. Keys would also respond if Guitarist makes it personal. You can add a label to Guitarist's choices (okay, I just did that!), and use that label like a variable adjust Keys' response...
|
|
|
|
{PERSONAL:
|
|
KEYBOARDIST: We did what we wanted to do. We made people happy. Can we please focus on that?
|
|
GUITARIST: Yeah. Well, I can. I won't speak for anyone else.
|
|
- else:
|
|
KEYBOARDIST: Okay, do I have to be happy for everyone? Because I'm prepared to do that.
|
|
GUITARIST: (laugh) I believe you. But, nah. I think we're good.
|
|
}
|
|
-> BAND_UNITY_CHECK
|
|
|
|
//NOTE: If band went into the performance with the highest unity score of +4 , but made all the negative choices in these dissenter stitches, the highest score they could have now is +1 , which is why that is the number we're checking against in the stitch below...
|
|
|
|
= BAND_UNITY_CHECK
|
|
|
|
{band_unity <= 1:
|
|
DRUMMER: Well, I didn't think you'd break up after your first song.
|
|
DRUMMER: But you're close. Very close. //MK: I wonder about talking about band unity in a way that highlights its metric nature. But maybe this line doesn't work.
|
|
- else:
|
|
DRUMMER: Congratulations! You've survived your first band betrayal.
|
|
KEYBOARDIST: That's the power of positivity!
|
|
}
|
|
|
|
+ SINGER: Okay, great. No harm done. #PRIVATE
|
|
+ SINGER: I don't want to make that mistake again. #PRIVATE
|
|
-
|
|
-> REVIEWS
|
|
|
|
= REVIEWS
|
|
|
|
BASSIST: Huh. We have a review. That's surprisingly quick.
|
|
|
|
SINGER: What's surprising is you paying attention to reviews.
|
|
|
|
KEYBOARDIST: You have a phone, {name_bassist}?
|
|
|
|
BASSIST: ... okay, I'm not a hermit.
|
|
|
|
{vocals_moodtattoo == "Anti-Tattoo":
|
|
|
|
BASSIST: Looks like we were not a hit with Upgraders. Apparently, our song was...
|
|
BASSIST: "like a knuckle-dragging technophobe conspiracy screed from the Old World".
|
|
|
|
GUITAR: Poor Upgraders. We should have called the song "Turn Me Into a Toaster".
|
|
|
|
BASSIST: Come on. They aren't that bad. We _do_ need to evolve ourselves.
|
|
|
|
KEYBOARDIST: The All-for-All Sezzit group is lit up. Everyone's cancelling their mood tattoos and booking therapy appointments. //MK: Sezzit...if we need a Reddit clone for this world. This does make me wonder about our fan groups need any introductions. So, I put a bit here.
|
|
SINGER: I thought the A4A crowd was all about group therapy already?
|
|
|
|
KEYBOARDIST: We are. It's great! I just thought people could do both.
|
|
|
|
GUITARIST: We just got atted by the tattoo staff out front. Like, in the venue. No one is getting a Mood Tattoo.
|
|
GUITARIST: (laugh) But, there's a huge line for anti-corporate traditional ink.
|
|
|
|
SINGER: Wow, yeah. They banned us. They said we went against the whole vibe of the show.
|
|
|
|
KEYBOARDIST: No! I don't like being banned!
|
|
|
|
SINGER: It's okay, {name_keyboardist}. "Giving us the finger is pretty badass, though", so we're cool again.
|
|
|
|
BASSIST: Gotta say... this is a fun ride.
|
|
|
|
- else:
|
|
|
|
BASSIST: Anyway, we "showed support for meat/metal integration by pushing tech tats". At least that's what some Upgraders are saying.
|
|
|
|
SINGER: Uh, in no way did I encourage the melding of human consciousness and thinking machines.
|
|
|
|
BASSIST: That's how Upgraders heard it. Don't blame the audience.
|
|
|
|
KEYBOARDIST: Oh my gosh. Like, so many people got mood tattoos during the show! These group selfies are so nice. Everyone is glowing!
|
|
|
|
GUITARIST: Sounds like serious All For All energy.
|
|
|
|
KEYBOARDIST: There's nothing wrong with people liking people. I can't wait to get mine.
|
|
KEYBOARDIST: And {name_singer} was shouted out for prompting a conversation with "off-brand fluffy positivity". Off-brand?
|
|
|
|
SINGER: Yeah... I don't usually go quite this huggy-wuggy. But, I'm glad to hear they're talking.
|
|
|
|
}
|
|
GUITARIST: Not everyone was talking. Did we all see those brooders at the back of the room?
|
|
|
|
BASSIST: Yeah. Unvoiced, I think. Didn't think "vow-of-silence" and "live music" went together.
|
|
//HJ: Here is a decent place for one of the characters (not Singer) to mention the strange silent people at the event, to set up The Unvoiced noise complaint letter for the OUTCOME scene.
|
|
-> FAN_REACTIONS
|
|
|
|
= FAN_REACTIONS
|
|
#PlaySFX: Akai_excited
|
|
DRUMMER: WE'RE NOT TOO LOUD. YOU'RE TOO OLD!
|
|
DRUMMER: (sigh) I'm ready to go whenever you are.
|
|
//NOTE: The team doesn't have time to design a social media interface for the CMF demo, so what I've done here is just split the characters out into their own screens and we'll write this as if they're on their devices reading the comments.
|
|
|
|
#SPLITFLOW
|
|
{
|
|
- char_singer:
|
|
{vocals_moodtattoo == "Anti-Tattoo":
|
|
-> SINGER_SOCIALS_ANTI //HJ: I just changed all these to ANTI or PRO because it's less letters.
|
|
- else:
|
|
-> SINGER_SOCIALS_PRO
|
|
}
|
|
|
|
- char_guitarist:
|
|
{
|
|
- vocals_moodtattoo == "Anti-Tattoo":
|
|
-> GUITARIST_SOCIALS_ANTI
|
|
- else:
|
|
-> GUITARIST_SOCIALS_PRO
|
|
}
|
|
|
|
- char_bassist:
|
|
{
|
|
- vocals_moodtattoo == "Anti-Tattoo":
|
|
-> BASSIST_SOCIALS_ANTI
|
|
- else:
|
|
-> BASSIST_SOCIALS_PRO
|
|
}
|
|
|
|
- char_keyboardist:
|
|
{
|
|
- vocals_moodtattoo == "Anti-Tattoo":
|
|
-> KEYS_SOCIALS_ANTI
|
|
- else:
|
|
-> KEYS_SOCIALS_PRO
|
|
}
|
|
}
|
|
|
|
= SINGER_SOCIALS_ANTI
|
|
SINGER: Oh, look at that. HearMeNot says I'm a "closed-minded fear monger". They're Unvoiced, for sure. #PRIVATE
|
|
+ [Defend the song.]
|
|
SINGER: "People should suspect and question anything that wants to keep them from speaking. We spoke that message, and it was heard."
|
|
SINGER: "If the song wasn't for you, so be it."
|
|
+ [Attack the Unvoiced.]
|
|
SINGER: "Closed-minded is rejecting the spoken word and exiling anyone who dares to use one.
|
|
SINGER: The Unvoiced embraces intolerance as well as silence."
|
|
-
|
|
SINGER: Boom. #PRIVATE
|
|
-> LEAVE_VENUE
|
|
|
|
= SINGER_SOCIALS_PRO
|
|
SINGER: Free mood tattoo? For "fostering togetherness and emotional connection"? #PRIVATE
|
|
|
|
+ [Decline, politely.]
|
|
SINGER: "Thank you! I prefer using my voice to connect with people. I'm glad to see it worked with you." #PRIVATE
|
|
+ [Refuse, bluntly.]
|
|
SINGER: "Hard pass. The Unvoiced created these tattoos. I hate silence as much as I love connection." #PRIVATE
|
|
SINGER: That... might confuse some people. I did just sing a pro-tattoo song. Oh, well. #private
|
|
+ [Don't respond.]
|
|
SINGER: Saying no might reflect poorly on the band. And I'd never say yes. #PRIVATE
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= GUITARIST_SOCIALS_ANTI
|
|
GUITARIST: What the hell is this?! #PRIVATE
|
|
GUITARIST: "As the face of the Politicats, {name_guitarist} didn't really believe in anything... #PRIVATE
|
|
GUITARIST: ... but is believing in _not_ doing something any better?" #PRIVATE
|
|
|
|
+ [Ignore them.]
|
|
GUITARIST: Probably won't reflect well on the band if I rip this asshole. #PRIVATE
|
|
+ [Defend yourself.]
|
|
GUITARIST: "Those tats are a shitty fad. I believe in not doing something just because people want you to. So BALLS YEAH, it's better." #PRIVATE
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= GUITARIST_SOCIALS_PRO
|
|
GUITARIST: "Your onstage aura needs its own light show!" Yeah, damn right... #PRIVATE
|
|
GUITARIST: "...so we'd love to give you a free mood tattoo." Oh, shit. I can't say "hell, no" now... #PRIVATE
|
|
|
|
+ [Book a tattoo appointment!]
|
|
GUITARIST: "Warm up the needle. I'm on my way!" #private
|
|
GUITARIST: Screw it. I've changed. Time to show it. #PRIVATE
|
|
+ [Put it off.]
|
|
GUITARIST: Uh.... "Busy giggin' but I'll get back to you ASAP." #PRIVATE
|
|
GUITARIST: There. They'll forget about it. And so will I. #PRIVATE
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= BASSIST_SOCIALS_ANTI
|
|
BASSIST: Creepy anonymous DM. Mysterious. #private
|
|
BASSIST: "So who's behind Mood Tattoos? What do you know?" I can just see this person chain-smoking. #PRIVATE
|
|
|
|
+ [Who cares? It's a song.]
|
|
BASSIST: "Everything is connected. Everything is twisted. That's what I know. It's all in the song." #PRIVATE
|
|
+ [Confirm the conspiracy.]
|
|
BASSIST: "Does it matter who Big Tattoo is? They want to know what you're feeling all the time. That's messed up, and we have to fight it." #PRIVATE
|
|
-
|
|
BASSIST: I'd love to blow the lid off of this. But if anyone should out the Unvoiced, it's {name_singer}. #PRIVATE
|
|
-> LEAVE_VENUE
|
|
|
|
= BASSIST_SOCIALS_PRO
|
|
BASSIST: "Free mood tattoo", huh?
|
|
|
|
+ [No.]
|
|
BASSIST: Probably better that people don't see my mood all the time. #PRIVATE
|
|
+ [Yeah, sure.]
|
|
BASSIST: ... as long I can hide it. I like being mysterious. #PRIVATE
|
|
-
|
|
|
|
-> LEAVE_VENUE
|
|
|
|
= KEYS_SOCIALS_ANTI
|
|
KEYBOARDIST: "Get a mood tattoo. Then judge them. I dare you!" This is aggressive. #private
|
|
|
|
+ [Accept the challenge.]
|
|
KEYBOARDIST: I wanted one, anyway. I'll show the band how fun they are. #PRIVATE
|
|
~ arc_keyboardist = "chearlead"
|
|
+ [Admit you love mood tattoos.]
|
|
KEYBOARDIST: "{band_name} is judging! {name_keyboardist} loves mood tattoos!"
|
|
KEYBOARDIST: This band is grim. I gotta fix that. #PRIVATE
|
|
The band needs to cheer up!
|
|
~ arc_keyboardist = "police"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
|
|
= KEYS_SOCIALS_PRO
|
|
KEYBOARDIST: Oh. My. Everything.
|
|
KEYBOARDIST: "Free mood tattoo to the first {name_keyboardist} of {band_name} to visit our shop!"
|
|
|
|
+ [Accept and lie about age.]
|
|
KEYBOARDIST: "The other {name_keyboardist}s might have to hide it from their parents, but not this {name_keyboardist}!" #PRIVATE
|
|
KEYBOARDIST: Ugh. That was so obvious. I probably should hide it, though. #PRIVATE
|
|
+ [Admit you're too young.]
|
|
KEYBOARDIST: "Hey, thanks! I turn 18 soon, and I'll bring my own cake!" #PRIVATE
|
|
KEYBOARDIST: I'll manage the band's vibe without it. For now. #PRIVATE
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= LEAVE_VENUE
|
|
#REJOIN
|
|
DRUMMER: For real, though, let's go.
|
|
-> OUTCOME_MOODTATTOOS
|