285 lines
13 KiB
Plaintext
285 lines
13 KiB
Plaintext
-> OUTCOME_MOODTATTOOS
|
|
|
|
=== OUTCOME_MOODTATTOOS ===
|
|
|
|
#Environment: PracticeSpace
|
|
|
|
SINGER: My 70 year-old neighbour stopped me this morning, to play _our_ song for me.
|
|
|
|
{vocals_moodtattoo == "Pro-Tattoo":
|
|
SINGER: We inspired him to get a mood tattoo. He was so excited to show it off.
|
|
|
|
BASSIST: The Mayor was goaded into getting one. They've already been caught lying about libraries and transit. It was hilarious.
|
|
|
|
KEYBOARDIST: More people have gotten them since our show than had them before. And Barista Beat is reporting a huge drop in coffee shop arguments!
|
|
|
|
BASSIST: So, everyone's latte is smiling a little wider...
|
|
|
|
- else:
|
|
SINGER: He was considering a mood tattoo "to stay young", but we talked him out of it.
|
|
|
|
GUITARIST: I saw a lot of graffiti on the way here. The word is _way_ out. People are talking about emotional privacy.
|
|
|
|
KEYBOARDIST: I'm worried about just creating trust issues in people.
|
|
|
|
BASSIST: Relax, {name_keyboardist}...
|
|
|
|
}
|
|
|
|
//HJ: Here, add a choice for Bassist to set arc variable. In Whale Song, these arc variables naturally set during the FAN_REACTIONS section, but in Mood Tattoos that didn't seem to work as well to me. So in the Miro, I put the characters' arc variables in the OUTCOME scene, and this is where Bassist's would go. Actually, Keys' arc can be set here too!
|
|
//MK: I put this before the letter. It was clunky the other way.
|
|
|
|
+ [Nothing will change.]
|
|
BASSIST: ... we're a long way from really changing anything.
|
|
//HJ: ^^The choice can be private, but Bassist could then say the choice line aloud to everyone else once it's chosen. Hence, no square brackets around this line. However, if you want Bassist to say something different aloud, put square brackets around the choice line.
|
|
~ arc_bassist = "cynical"
|
|
|
|
++ KEYBOARDIST: So, we shouldn't quit now? I'm sure that's what you mean.
|
|
~ arc_keyboardist = "police"
|
|
++ KEYBOARDIST: So, I have to keep us smiling until we do!
|
|
~ arc_keyboardist = "cheerlead"
|
|
--
|
|
|
|
+ [This is just the beginning.]
|
|
BASSIST: ... maybe our song will inspire people to do better. #PRIVATE
|
|
~ arc_bassist = "hopeful"
|
|
//HJ: To trigger Keys response to this, someone needs to be a downer! Probably Akai. He's probably disillusioned with humankind.
|
|
DRUMMER: "Better" isn't something that people do.
|
|
|
|
++ KEYBOARDIST: Maybe you should control your "negativity" programming, too.
|
|
~ arc_keyboardist = "police"
|
|
++ KEYBOARDIST: Sure it is. Bandocracy proves it!
|
|
~ arc_keyboardist = "cheerlead"
|
|
--
|
|
-
|
|
|
|
BASSIST: In other news... I found a throwback angry letter by the front door. Congratulations, {band_name}, we have our first noise complaint.
|
|
|
|
GUITARIST: Pretty weird to complain about how loud music is, but whatever.
|
|
|
|
BASSIST: The Unvoiced in attendance "were subjected to unwanted vocal interference" at our show.
|
|
|
|
KEYBOARDIST: The other performances were instrumental and electronic. But, no one said we couldn't sing. Why were they even there?
|
|
|
|
//MK: You didn't mention when to reveal it, and it was used as Singer's secret in your Miro, so I'll put it here....
|
|
SINGER: Probably because... the Unvoiced created Mood Tattoos.
|
|
//MK: Does feel a bit clunky, though. We should massage the Unvoiced secret. //HJ: Agreed. Let's have one of the characters mention the strange silent people at the event in the POST_PERFORM_MOODTATTOOS scene, to set this up.
|
|
|
|
{
|
|
- vocals_moodtattoo == "Anti-Tattoo":
|
|
BASSIST: That's why they're saying we "are trying to destroy the purity of non-vocal communication and encourage verbal conflict".
|
|
|
|
SINGER: Yeah, that was the whole point. They should be happy I didn't call them out by name.
|
|
- vocals_moodtattoo == "Pro-Tattoo":
|
|
BASSIST: Even though we supported mood tattoos, we "reduced them to a simplistic mood-ring equivalent fad".
|
|
|
|
SINGER: That's better than they deserved. At least I didn't call them out by name.
|
|
}
|
|
|
|
SINGER: Let me see the letter, {name_bassist}.
|
|
|
|
KEYBOARDIST: The Unvoiced created mood tattoos? Why didn't you tell us? How did you even know?
|
|
|
|
SINGER: ... this is Mom's handwriting... #PRIVATE
|
|
|
|
+ [SINGER: I should tell them.] #PRIVATE
|
|
-> SINGER_REVEALS_MOM
|
|
+ [SINGER: I can't mention that.] #PRIVATE
|
|
-> SINGER_KEEPS_MOM_SECRET
|
|
|
|
= SINGER_KEEPS_MOM_SECRET
|
|
SINGER: I heard it from someone who left the cult.
|
|
//MK: I tried to keep the structure from the Whale Song scene so we could keep Guitar outing Singer's mom. In this world, I think Guitar would do that if they felt like Singer "forced" them into supporting mood tattoos as a weak attempt to make things up to mom. Mean! If it doesn't work for you, it can just come out.
|
|
//HJ: That motivation makes sense to me. We'll either need to set a special variable for that (since Guitarist's arc variable is set later in this script), OR you can make this the Guitarist's choice of how to respond. //MK: how does it feel here? I'm not sure if it's too harsh if G just says it.
|
|
{
|
|
- its_personal == "true": //HJ: Either need a new variable OR turn this Conditional Block into a Choice Block. //MK: just went with this one, linked to PERSONAL. You might want to change where it's set in POST_PERFORMANCE, but there's no error.
|
|
GUITARIST: Or from someone who didn't. Like your mom, maybe.
|
|
BASSIST: {name_singer}, your mom is InDulcet, isn't she? Or, wasn't she, I guess.
|
|
SINGER: Yeah. She was. Then she gave up her voice and tried to take mine. But, as {name_guitarist} should know, I can still speak for my damn self.
|
|
~ band_knows_about_singer_mom = true
|
|
|
|
-> SINGER_MOM_FEELS
|
|
- else: //MK: Decided just to remove the neutral reply for G. If they aren't pissed, they'd probably care a little.
|
|
GUITARIST: Don't let that letter bug you. No matter what's in it.
|
|
SINGER: Thanks. I'll try. //HJ: With Keys and Bassist there, will these messages pass between Singer and Guitarist with simple looks and private thoughts? Since they can't say this aloud and still keep the secret.
|
|
|
|
}
|
|
SINGER: She wasn't there. I didn't see her. Why did she write this? #PRIVATE
|
|
|
|
+ [SINGER: Maybe this is Mom's way of reaching out.] #PRIVATE
|
|
~ arc_singer = "hopeful"
|
|
+ [SINGER: Even after all these years, Mom can't resist scolding me.] #PRIVATE
|
|
~ arc_singer = "bitter"
|
|
-
|
|
-> BASSIST_IMPRESSED
|
|
|
|
= SINGER_REVEALS_MOM
|
|
~ band_knows_about_singer_mom = true
|
|
SINGER: My mom is Unvoiced. And this is her handwriting.
|
|
{
|
|
- its_personal == "true": //HJ: Same note as above - need to creat a variable tracking Guitarist's previous response, OR make this a Choice Block for Guitarist to respond now.
|
|
GUITARIST: If this whole thing was just to apologize to your mom for leaving her cult...
|
|
GUITARIST: ... it didn't work.
|
|
SINGER: In case the rest of you are wondering why I didn't mention this earlier...
|
|
SINGER: This is why. Because {name_guitarist} would use it against me.
|
|
- else:
|
|
GUITARIST: It's been a while since you last heard from her. Are you okay?
|
|
SINGER: Yeah, it has. And I don't know. Not yet.
|
|
|
|
}
|
|
|
|
BASSIST: Is your mom InDulcet? I remember her leaving the scene. She had a great voice.
|
|
SINGER: Yeah, she did. And then she stopped using it. I wouldn't let her stop me from using mine.
|
|
BASSIST: I understand why you'd keep that secret. Her shadow must be a long, dark one.
|
|
KEYBOARDIST: I've never heard of InDulcet. But I'm glad she couldn't stop you from singing.
|
|
-> SINGER_MOM_FEELS
|
|
|
|
= SINGER_MOM_FEELS
|
|
|
|
+ SINGER: Maybe this is Mom's way of reaching out.
|
|
~ arc_singer = "hopeful"
|
|
+ SINGER: Even after all these years, Mom can't resist scolding me.
|
|
~ arc_singer = "bitter"
|
|
-
|
|
-> BASSIST_IMPRESSED
|
|
|
|
= BASSIST_IMPRESSED
|
|
BASSIST: Whatever else is in that letter... we got a complaint. That means we made an impact. You're voice made an impact, {name_singer}.
|
|
|
|
KEYBOARDIST: Yeah, no one complains if they don't care. Well, I don't complain at all. Too negative. But yes. Impact made.
|
|
|
|
{its_personal == "false":
|
|
GUITARIST: Gotta say, {name_singer}... you're doing a great job. You're already a better bandleader than I ever was.
|
|
}
|
|
|
|
SINGER: Thanks. But it's just words on a page without music. And they music is all you.
|
|
|
|
BASSIST: Okay, I have to go a bit harder, here.
|
|
BASSIST: I was going to quit, but I joined this band to play with you. This is my last band, no matter what.
|
|
|
|
{vocals_moodtattoo == "Anti-Tattoo": //HJ: I think the Anti-Tattoo lyrics would make Singer most confident.
|
|
SINGER: Well, then. I guess I have some hits to write.
|
|
- else:
|
|
SINGER: I... won't let you down. I won't let any of you down.
|
|
}
|
|
|
|
DRUMMER: Hey, so you pay money to rent this place. Maybe you'd like to practice.
|
|
DRUMMER: Or you could emote some more. I'll just go into "bored" mode.
|
|
|
|
SINGER: No, don't. The snoring is so weird. We'll practice.
|
|
|
|
{its_personal == "true": //HJ: Again, use the new variable or label here.
|
|
SINGER: I just have to talk to {name_guitarist} first. Now.
|
|
-> CONVO_GUITAR_APOLOGY
|
|
- else:
|
|
GUITAR: Uh, {name_singer}... can I talk to you for a sec?
|
|
-> CONVO_GUITAR_ASSURANCE
|
|
}
|
|
|
|
= CONVO_GUITAR_APOLOGY //MK: The critic only pops up in GUITARIST_SOCIALS_ANTI, so I did this...
|
|
SINGER: At the risk of obliterating forever my reputation for articulate and erudite lyricism...
|
|
SINGER: What the hell is up your ass?!
|
|
|
|
{
|
|
- (vocals_moodtattoo == "Pro-Tattoo"):
|
|
GUITARIST: Me? You forced me into a pro-tattoo stance, and now people expect me to get one!
|
|
GUITARIST: You know how scared I am to show what's inside me, after what happened!
|
|
GUITARIST: Was all of this shit just to be nice to mom?
|
|
|
|
- (vocals_moodtattoo == "Anti-Tattoo"):
|
|
|
|
GUITARIST: You made yourself look like a badass, but I'm getting called out by old critics.
|
|
GUITARIST: It looks like the only thing I believe in is _not_ believing in something.
|
|
GUITARIST: You went your own way with this song, just to dunk on mommy.
|
|
}
|
|
SINGER: My performance - my choices - had nothing to do with my mom.
|
|
SINGER: So don't act like I'm the asshole, here.
|
|
|
|
GUITAR: Hey, I know I'm the other asshole. But you know what's up with me.
|
|
|
|
SINGER: And you know what a wound my mother is for me. You had no right to bring her up.
|
|
|
|
-> CONVO_KEYS_BASSIST
|
|
|
|
= CONVO_GUITAR_ASSURANCE
|
|
GUITAR: I want you to know... this band is going to be different. I'm different.
|
|
GUITAR: This is your thing, and I'm glad to be here. Thanks.
|
|
|
|
SINGER: I know you're trying. I can see it. But you're still hung up on what you want for yourself. Sorry... but, I'm concerned.
|
|
|
|
-> CONVO_KEYS_BASSIST
|
|
|
|
= CONVO_KEYS_BASSIST
|
|
|
|
KEYBOARDIST: Hey, {name_bassist}... did you say this is your last band? Like... last?
|
|
|
|
BASSIST: Yeah, this is it. Honestly, I surprised myself when I showed up for the audition.
|
|
|
|
KEYBOARDIST: And we're on our way. Aren't you glad you tried again?
|
|
|
|
{arc_bassist == "hopeful":
|
|
BASSIST: I'd say I'm... willing to be pleasantly surprised. Trust me, that's better than normal.
|
|
- else:
|
|
BASSIST: I don't get my hopes up. Not anymore.
|
|
}
|
|
|
|
{arc_keyboardist == "police":
|
|
KEYBOARDIST: Please don't bring anyone else down. Some of us have never been in a band.
|
|
- else:
|
|
KEYBOARDIST: That's not a {band_name} attitude! We can do better than that!
|
|
}
|
|
|
|
BASSIST: Okay. I'll try to keep the darkness on my own moods. Promise.
|
|
|
|
KEYBOARDIST: And I promise I'll keep you upbeat.
|
|
|
|
{vocals_moodtattoo == "Pro-Tattoo":
|
|
KEYBOARDIST: But I hope our messages can be a bit... bigger.
|
|
- else:
|
|
KEYBOARDIST: I won't let the negativity of our first song get to me.
|
|
|
|
}
|
|
KEYBOARDIST: How do I know if this band is the right fit for me?
|
|
|
|
BASSIST: You'll know. You won't be one hundred percent behind everything, but if you quit because of that, you'll never feel like you're part of something.
|
|
BASSIST: You should only quit after a long career drains the energy out of you.
|
|
|
|
KEYBOARDIST: Oh, no.
|
|
|
|
BASSIST: That was a joke.
|
|
|
|
KEYBOARDIST: Oh! (laughs)
|
|
|
|
-> CONVO_SINGER_GUITAR
|
|
|
|
= CONVO_SINGER_GUITAR
|
|
|
|
SINGER: And, in this band, I won't be the one who leaves early.
|
|
|
|
{
|
|
- (its_personal == "true") && (vocals_moodtattoo == "Pro-Tattoo"):
|
|
GUITAR: And you're not the one who sounds like a fraud. Again. It doesn't feel good, you know?
|
|
SINGER: You're only a fraud if you lie about what you feel.
|
|
SINGER: Do you feel badly because of what you did, or because you got caught?
|
|
- (its_personal == "true") && (vocals_moodtattoo == "Anti-Tattoo"):
|
|
GUITAR: And you're not the one who'll be carrying past mistakes around, forever. What do people want from me?
|
|
SINGER: What do you want for yourself? To change, or just to forget about the past?
|
|
}
|
|
|
|
+ GUITARIST: You'll never be happy. You just want to judge me.
|
|
~ arc_guitarist = "egocentric"
|
|
+ GUITARIST: I guess I'm not sure. That's my problem.
|
|
~ arc_guitarist = "humbled"
|
|
-
|
|
|
|
GUITAR: I don't know what I believe in. I've never even talked about it. Or us.
|
|
GUITAR: Maybe, if you want, we could grab a drink. Feels like we're starting to clear the air.
|
|
|
|
+ SINGER: Yeah. I'd like that.
|
|
SINGER: If they're willing to try, I'm willing to help. #PRIVATE
|
|
|
|
+ SINGER: I don't think that's a good idea.
|
|
SINGER: I'd rather not get dragged back into... this. #PRIVATE
|
|
|
|
-
|
|
-> SONG_TOPICS_L2 |