BloomDigital
/
Bandocracy-ink
5
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity
Bandocracy-ink/Level1/PRACTICE_WHALESONG.ink

853 lines
23 KiB
Plaintext
Raw Blame History

This file contains ambiguous Unicode characters

This file contains Unicode characters that might be confused with other characters. If you think that this is intentional, you can safely ignore this warning. Use the Escape button to reveal them.

=== PRACTICE_WHALESONG ===
SINGER: Okay! If we do this right, we can really make a statement.
SINGER: And we could make that statement in Whaleish.
KEYBOARDIST: You mean... write it in Whale? Sing it in Whale?
SINGER: Some of it, yeah. I did learn Whaleish in school.
KEYBOARDIST: Sing it in Whale! That would make such a SPLASH! Haha!
GUITARIST: Woah. That feels like a big risk for our first song.
SINGER: You don't think I can do it?
GUITARIST: Hey, if anyone can do it, it's you. But people might call it a gimmick.
GUITARIST: And we don't want to say the wrong thing. Right?
BASSIST: I don't think {name_singer} would write gibberish in any language.
BASSIST: But Whales don't need to hear this message. Humans do.
GUITARIST: Yeah. That, too. Whaleish might confuse them.
SINGER: It sounds like we all want to say the same thing.
SINGER: So, the issue is the lyrics. Whaleish or no whaleish.
DRUMMER: So, it's voting machine time.
#SPLITFLOW
{
- char_singer:
-> SINGER_THOUGHTS
- char_guitarist:
-> GUITARIST_THOUGHTS
- char_bassist:
-> BASSIST_THOUGHTS
- char_keyboardist:
-> KEYBOARDIST_THOUGHTS
}
= SINGER_THOUGHTS
+ [I hear {name_bassist}, but some people always miss the message.]
+ [{name_guitarist} is wrong. Whaleish lyrics aren't gimmicky.]
SINGER: {name_guitarist} is just worried no one will pay attention to the guitar. #THOUGHT
-
SINGER: And I wouldn't write the _whole_ song in Whaleish. #THOUGHT
SINGER: Plus, the festival will be full of people like {name_keyboardist} who'd love to hear a song in Whaleish. #THOUGHT
SINGER: I just wish singing in Whaleish didn't scare me so much... #THOUGHT
-> VOTE_TIME
= GUITARIST_THOUGHTS
GUITARIST: {name_singer}'s gotta understand {name_bassist}'s point. #THOUGHT
+ [Whaleish lyrics will totally confuse people!]
+ [The whales don't need to hear the message.]
-
GUITARIST: And if we alienate people, it won't matter how important the message is. #THOUGHT
GUITARIST: It is important, though. And it could make a splash, like {name_keyboardist} said. #THOUGHT
GUITARIST: But, if the whaley sounds get all the attention... no one will even notice me. #THOUGHT
-> VOTE_TIME
= BASSIST_THOUGHTS
BASSIST: Humans don't even listen to human voices. They'll tune out Whaleish completely. But... #THOUGHT
+ [I hope {name_singer} has the guts to go for it.]
+ [I doubt {name_singer} will do it. Even though...]
-
BASSIST: It could make a... splash. #THOUGHT
BASSIST: I hope that's the last pun we get from {name_keyboardist}. I almost laughed. #THOUGHT
-> VOTE_TIME
= KEYBOARDIST_THOUGHTS
KEYBOARDIST: So many votes! So many chances to disagree! #THOUGHT
+ [I don't want to disagree with my first band.]
+ [We're totally going to break up!!!]
-
KEYBOARDIST: But maybe this is normal band stuff. I'll find out. #THOUGHT
KEYBOARDIST: But I hope the Whales don't find out I failed Conversational Whaleish. #THOUGHT
-> VOTE_TIME
= VOTE_TIME
#REJOIN
#PlayerControlUntil: VoteComplete, JumpToPath: PRACTICE_WHALESONG.VOTE_RESULTS
+ [VOTE ON IT!]
-> VOTE
= VOTE
{
- char_singer:
-> VOTE_SINGER
- char_guitarist:
-> VOTE_GUITARIST
- char_bassist:
-> VOTE_BASSIST
- char_keyboardist:
-> VOTE_KEYBOARDIST
}
= VOTE_SINGER
+ [Include Whaleish lyrics.]
~ vote_songstance_whaleish++
+ [Only Human lyrics.]
~ vote_songstance_human++
-
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
-> VOTE_RESULTS
= VOTE_GUITARIST
+ [Include Whaleish lyrics.]
~ vote_songstance_whaleish++
+ [Only Human lyrics.]
~ vote_songstance_human++
-
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
-> VOTE_RESULTS
= VOTE_BASSIST
+ [Include Whaleish lyrics.]
~ vote_songstance_whaleish++
+ [Only Human lyrics.]
~ vote_songstance_human++
-
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
-> VOTE_RESULTS
= VOTE_KEYBOARDIST
+ [Include Whaleish lyrics.]
~ vote_songstance_whaleish++
+ [Only Human lyrics.]
~ vote_songstance_human++
-
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
{shuffle:
-
~ vote_songstance_whaleish++
-
~ vote_songstance_human++
}
-> VOTE_RESULTS
= VOTE_RESULTS
{
- vote_songstance_whaleish == 4:
~ band_unity +=2
-> STANCE_WHALEISH
- vote_songstance_whaleish == 3:
~ band_unity +=1
-> STANCE_WHALEISH
- vote_songstance_human == 4:
~ band_unity +=2
-> STANCE_HUMAN
- vote_songstance_human == 3:
~ band_unity +=1
-> STANCE_HUMAN
- else:
{not TIE_RULES: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE } //If players have not heard the TIE RULES, go there in the event of a tie vote. Otherwise, players already know the rule is Drummer's Choice.
}
= TIE
~ vote_songstance_whaleish = 0
~ vote_songstance_human = 0
//Reset votes ^ and send players back to VOTE...
#PlayerControlUntil: VoteComplete, JumpToPath: PRACTICE_WHALESONG.VOTE_RESULTS
+ [Vote again!]
-> VOTE
= DRUMMER_CHOICE
~ band_unity-- //band couldn't agree, so band unity drops.
DRUMMER: I have to break the tie. Feel free to get mad at the result.
{shuffle:
-
-> STANCE_WHALEISH
-
-> STANCE_HUMAN
}
= STANCE_WHALEISH
DRUMMER: The song will include Whaleish lyrics!
~ band_stance_L1 = "Rebels"
~ song_stance_L1 = "Whaleish"
/*NOTE: I created 2 variables in order to...
1) compare band_stance to band_vision to see if they're equal or not, and thus these variables need the same values, "Rebels" or "People".
2) compare song_stance_L1 to vocals_whalesong, the same way as above, using the values "Whaleish" or "Human".
*/
#SPLITFLOW
{
- char_singer:
-> SINGER_FEELS_WHALEISH
- char_guitarist:
-> GUITARIST_FEELS_WHALEISH
- char_bassist:
-> BASSIST_FEELS_WHALEISH
- char_keyboardist:
-> KEYS_FEELS_WHALEISH
}
= SINGER_FEELS_WHALEISH
//For Singer, there are PROS and CONS to both stances, so Singer gets ALL the choice reactions.
+ [Yes, I'll be the first human to perform in Whaleish!]
+ [Oh no, I'm going to blow this.]
SINGER: Ha. A whale pun. My writing already sucks. #THOUGHT
+ [So, the pressure is on.]
-
{DRUMMER_CHOICE:
SINGER: And Akai is billing me extra for tiebreaking. I know it. #THOUGHT
}
-> WHALESONG_STEMS
= GUITARIST_FEELS_WHALEISH
{DRUMMER_CHOICE:
GUITARIST: Surprise! The robot votes the way the boss wants.
}
+ [I might as well not even play on this song.]
+ [Fine. Rolling with this will prove I'm a better bandmate now.]
-
-> WHALESONG_STEMS
= BASSIST_FEELS_WHALEISH
+ [Huh. Now I'm excited.]
BASSIST: People might ignore it, but {name_singer} will rock those Whale vocals.
+ [This is a mistake.]
BASSIST: No one ever listens. I'm not just "being negative".
+ [Whatever.]
BASSIST: I did my part and warned them. If they have faith in people, that's their problem.
-
{DRUMMER_CHOICE:
BASSIST: Maybe Akai wants the message to fail. That'd be hilarious.
}
-> WHALESONG_STEMS
= KEYS_FEELS_WHALEISH
+ [Yes! Playing for Whales at my first gig!]
+ [I should be excited, but I'm not. Why not?]
KEYBOARDIST: Maybe {name_guitarist} and {name_bassist} are bringing me down a bit. #THOUGHT
KEYBOARDIST: But I shouldn't let their non-excitement ruin my excitement. #THOUGHT
-
{DRUMMER_CHOICE:
KEYBOARDIST: I'm glad Akai can choose, so we don't start fighting.
}
-> WHALESONG_STEMS
= STANCE_HUMAN
DRUMMER: The song will NOT include Whaleish. Human lyrics only!
~ band_stance_L1 = "People"
~ song_stance_L1 = "Human"
#SPLITFLOW
{
- char_singer:
-> SINGER_FEELS_HUMAN
- char_guitarist:
-> GUITARIST_FEELS_HUMAN
- char_bassist:
-> BASSIST_FEELS_HUMAN
- char_keyboardist:
-> KEYS_FEELS_HUMAN
}
= SINGER_FEELS_HUMAN
+ [Wow. I'm actually pretty relieved.]
SINGER: I was worried about singing in Whaleish. Now, that won't affect my performance. #THOUGHT
+ [(slumps) They don't believe I could pull off singing Whaleish.]
+ [The message is the same, even if it's less inclusive.]
-
-> WHALESONG_STEMS
= GUITARIST_FEELS_HUMAN
+ [Awesome. Time for a comeback!]
GUITARIST: With no whale sounds to drown me out. #THOUGHT
+ [I bet {name_singer} is relieved.]
GUITARIST: They were nervous about singing Whaleish on stage. I know it. #THOUGHT
-
-> WHALESONG_STEMS
= BASSIST_FEELS_HUMAN
+ [Good. No distractions. No excuses. Humans suck.]
+ [Damn. I'm kinda sorry I won this one.]
BASSIST: {name_singer} would've rocked those Whaleish vocals!
-
{DRUMMER_CHOICE:
BASSIST: I hope Akai enjoys breaking ties. Lotta responsiblity.
}
-> WHALESONG_STEMS
= KEYS_FEELS_HUMAN
+ [Noooo! I wanted Whaleish lyrics!]
+ [It's okay. The message is what's important.]
-
{DRUMMER_CHOICE:
KEYBOARDIST: Akai probably feels bad about choosing randomly.
KEYBOARDIST: He'd want to help other species, for sure. Because... robots are a species.
KEYBOARDIST: Just like whales! They have so much in common!
}
-> WHALESONG_STEMS
=== WHALESONG_STEMS ===
#REJOIN
DRUMMER: While you all were reacting to the vote, I created two complete percussion tracks.
DRUMMER: We can have a Shore Party...
#PlayMusic: drums_whalesong_human
//formerly drums_whalesong_onland, but I want the names to be consistent with the stance labels.
DRUMMER: Or, we can go all AquaDrum...
#PlayMusic: drums_whalesong_whaleish
//formerly drums_whalesong_underwater
{song_stance_L1 == "Whaleish":
GUITARIST: Woah. Whale singing is already too much. We can't have underwater drums.
GUITARIST: I can't be the only one worried about being drowned out by whaley stuff.
BASSIST: I'm more worried about putting novelty over substance.
KEYBOARDIST: If we're going whale, let's go full whale!
- else:
KEYBOARDIST: Can we at least have the whaley beat?
BASSIST: Yeah, we have to push people out of their comfort zone a little.
GUITARIST: We're overthinking. Let's just make a banger.
}
SINGER: We need to start writing, so pick a beat everyone!
#PlayerControlUntil: VoteComplete, JumpToPath: WHALESONG_STEMS.VOTE_RESULTS
+ [VOTE ON THE BEAT!]
-> VOTE_DRUMS
= VOTE_DRUMS
{
- char_singer:
-> VOTE_SINGER
- char_guitarist:
-> VOTE_GUITARIST
- char_bassist:
-> VOTE_BASSIST
- char_keyboardist:
-> VOTE_KEYBOARDIST
}
= VOTE_SINGER
+ [AquaDrum.]
~ vote_whalesong_drums_whaleish++
+ [Shore Party.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_GUITARIST
+ [AquaDrum.]
~ vote_whalesong_drums_whaleish++
+ [Shore Party.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_BASSIST
+ [AquaDrum.]
~ vote_whalesong_drums_whaleish++
+ [Shore Party.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_KEYBOARDIST
+ [AquaDrum.]
~ vote_whalesong_drums_whaleish++
+ [Shore Party.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_RESULTS
{
- vote_whalesong_drums_whaleish >= 3:
DRUMMER: Votes are in and it's...
~ drums_whalesong = "Whaleish"
-> DRUMS_WHALEISH
- vote_whalesong_drums_human >= 3:
DRUMMER: Votes are in and it's...
~ drums_whalesong = "Human"
-> DRUMS_HUMAN
- else:
{not TIE_RULES: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE } //If players have not heard the TIE RULES, go there in the event of a tie vote. Otherwise, players already know the rule is Drummer's Choice.
}
= TIE
~ vote_whalesong_drums_whaleish = 0
~ vote_whalesong_drums_human = 0
//Reset votes ^ and send players back to VOTE...
#PlayerControlUntil: VoteComplete, JumpToPath: WHALESONG_STEMS.VOTE_RESULTS
+ [Vote again!]
-> VOTE_DRUMS
= DRUMMER_CHOICE
DRUMMER: I got this.
{shuffle:
-
~ drums_whalesong = "Whaleish"
-> DRUMS_WHALEISH
-
~ drums_whalesong = "Human"
-> DRUMS_HUMAN
}
= DRUMS_WHALEISH
DRUMMER: AquaDrum!
-> CHOOSE_MUSIC_STEMS
= DRUMS_HUMAN
DRUMMER: Shore Party!
-> CHOOSE_MUSIC_STEMS
= CHOOSE_MUSIC_STEMS
DRUMMER: The beat is chosen!
DRUMMER: Now you can write your parts. You'll need more time, of course.
#SPLITFLOW
//Players go into private screens to play their musical parts and decide which to choose.
{
- char_singer:
-> VOCAL_STEMS
- char_guitarist:
-> GUITAR_STEMS
- char_bassist:
-> BASS_STEMS
- char_keyboardist:
-> KEYS_STEMS
}
//NOTE: UI/UX for this just has 2 buttons on screen, with a dialogue bubble. For it to make sense in ink, I wrote it like this, but we'll need to actually talk about how the engine needs to interpret this section.
= VOCAL_STEMS
+ [Sing human language lyrics.]
#PlayMusic: vocals_whalesong_human
SINGER: {&I'd rather stick to human lyrics.|Will the whales connect with human lyrics?|It's an important message no matter what language it's in.|"Say it don’t spray it" - seriously!}
-> VOCAL_STEMS
+ [Sing Whaleish lyrics.]
#PlayMusic: vocals_whalesong_whaleish
SINGER: {&The whales will love this, IF I can sing it.|I'll be the first person ever to sing in Whaleish.|I learned Whaleish from a human. I hope they were right.|Ugh, my Whaleish probably sounds like Seal by now.}
-> VOCAL_STEMS
+ [Choose human lyrics.]
~ vocals_whalesong = "Human"
-> WHALESONG_JAM
+ [Choose Whaleish lyrics.]
~ vocals_whalesong = "Whaleish"
-> WHALESONG_JAM
= GUITAR_STEMS
+ [Play rocking guitar solo.]
#PlayMusic: guitar_whalesong_human
GUITARIST: {& It wouldn't be a "me" track without a solo.|{name_singer} always preferred the spotlight on me. Probably still does.|Sorry, whales. I do the whaling.}
-> VOCAL_STEMS
+ [Play backup whaley guitar.]
#PlayMusic: guitar_whalesong_whaleish
GUITARIST: {&This riff is whaley, but doesn't rock like the other one.|I wanna debut with a solo that rocks, but...|This whaley riff will prove I care most about the message, not myself.}
-> VOCAL_STEMS
+ [Choose rocking solo.]
~ guitar_whalesong = "Human"
-> WHALESONG_JAM
+ [Choose whaley guitar.]
~ guitar_whalesong = "Whaleish"
-> WHALESONG_JAM
= BASS_STEMS
+ [Play pop bass.]
#PlayMusic: bass_whalesong_human
BASSIST: {&Everyone likes a classic bassline.|But is this deep enough to penetrate the ocean?|This bassline might not be salty enough for the whales.}
-> VOCAL_STEMS
+ [Play deep oceany bass.]
#PlayMusic: bass_whalesong_whaleish
BASSIST: {&Smooth. Like a whale. I think whales are smooth.|Might as well dive deep.|This bassline evokes whale power.}
-> VOCAL_STEMS
+ [Choose pop bass.]
~ bass_whalesong = "Human"
-> WHALESONG_JAM
+ [Choose deep oceany bass.]
~ bass_whalesong = "Whaleish"
-> WHALESONG_JAM
= KEYS_STEMS
+ [Play pop chords.]
#PlayMusic: keys_whalesong_human
KEYS: {&Simple and safe. But still fun, I hope.|Will our cetacean siblings like these chords?|Maybe whaley harmonics are better.}
-> VOCAL_STEMS
+ [Play whaley harmonics.]
#PlayMusic: keys_whalesong_whaleish
KEYS: {&Cool! Synthesized whale sounds to harmonize with the vocals!|No such thing as too much whale!|THIS will Float the Vote!}
-> VOCAL_STEMS
+ [Choose pop chords.]
~ keys_whalesong = "Human"
-> WHALESONG_JAM
+ [Choose whaley harmonics.]
~ keys_whalesong = "Whaleish"
-> WHALESONG_JAM
=== WHALESONG_JAM ===
#REJOIN
DRUMMER: ONE! EIGHT! FIVE!
GUITARIST: Is your personality program messing with your math?
DRUMMER: ... Let's just jam.
#PlayMusic: {drums_whalesong}
#PlayMusic: {vocals_whalesong}
#PlayMusic: {guitar_whalesong}
#PlayMusic: {bass_whalesong}
#PlayMusic: {keys_whalesong}
//NOTE: I have to talk to JP about the above. I think this might trigger the music stems a split second apart, which will sound like crap. We might need a different command for this, but for now, you get the idea.
{song_stance_L1 == vocals_whalesong: //Check if stance the band chose and lyrics the singer chose are the same.
-> LYRICS_MATCH_STANCE
- else:
-> DISSENTER_SINGER
}
= LYRICS_MATCH_STANCE
+ Cool, we sound great!
+ Whoa. We sound weird.
Good weird? Bad weird? Audience's choice!
+ Wow, we are musical geniuses!
- //HJ: I think we need a moment to acknowledge the song after they "play" their parts together for the first time but before they comment on the vocals. Not a consequential choice, just another group reaction that the players can discuss IRL.
{song_stance_L1 == "Whaleish":
-> WHALEISH_SONG
- else:
-> HUMAN_SONG
}
= WHALEISH_SONG
GUITARIST: I... didn't know you could make those sounds, {name_singer}.
BASSIST: I think you just said "blow it out your hole"?!
BASSIST: Just kidding. You sound great.
KEYBOARDIST: OooooOOOOOooo! That wasn't me doing whale. That was me impressed!
SINGER: I mean, the whales might roast my pronunciation... but, thanks.
-> LOCKED_SONG
= HUMAN_SONG
GUITARIST: It's loud. It hits. No distractions.
BASSIST: No one can hide from the point.
KEYBOARDIST: You know what? I don't miss the Whaleish.
SINGER: Full disclosure... I wrote it in Whaleish and translated it for humans!
-> LOCKED_SONG
//NOTE: Since everyone is in agreement, we don't need to give players a choice to change or "lock in" their musical choices. We can simply move on.
= DISSENTER_SINGER
DRUMMER: Hold on a second! Something's wrong... //HJ: Like the choice block in LYRICS_MATCH_STANCE, I felt we needed a transition line to get into the characters' reactions to the lyrics.
{vocals_whalesong == "Whaleish":
GUITARIST: Yeah, {name_singer}. Why are you singing in Whaleish?
KEYBOARDIST: I love this. But... we were all on a page...
BASSIST: I get it. You heard this a certain way. But don't go rogue.
- else:
KEYBOARDIST: Where's the Whale? Why no Whale?
GUITARIST: Hey, {name_singer} sounds great! No Whale needed! //MK: I put this in, but I'm confused. Are people on the same page after the vote, or not? If not, and they stick to their in-scene stated preferences, they should do that all the time and be able to reference the preferences of others earlier. //HJ: Guitarist never has a fully positive reaction to Whaleish lyrics, G was resigned at best, so G would support S not singing Whaleish here.
BASSIST: Don't chicken out, {name_singer}. I'm not saying that's what you're doing...
BASSIST: But you don't have to.
}
SINGER: I hear you. Thanks for speaking up. //HJ: I think the Singer should respond to the challenge above. After all, everyone is basically asking them why they didn't stick to the lyrics they agreed on. They need to give their bandmates some kind of an answer. I put a couple ideas in the choice block below... //MK: I agree. I just didn't do that because you said not to give choices like this because other players would be waiting on them. //HJ: Yeah, but now we're gonna try it since it seems like a useful mechanic.
+ SINGER: I shouldn't have gone rogue like that.
+ SINGER: I wrote the lyrics I think are best.
-
DRUMMER: So... you all good with your choices? Or are you changing things up?
#PlayerControlUntil: StemsLocked, JumpToPath: WHALESONG_JAM.LOCKED_SONG
+ [BUTTONS POP UP - "Lock it in." or "Change it."]
-> CHANGE_STEMS
= CHANGE_STEMS
//NOTE: This won't be in split flow anymore, and the choices below are just for singleplayer Inky playthough purposes.
{
- char_singer:
-> SINGER_STEM_LOCK
- char_guitarist:
-> GUITARIST_STEM_LOCK
- char_bassist:
-> BASSIST_STEM_LOCK
- char_keyboardist:
-> KEYS_STEM_LOCK
}
= SINGER_STEM_LOCK
+ [Keep the lyrics.]
+ [Change them!]
++ [Whaleish lyrics.]
~ vocals_whalesong = "Whaleish"
++ [Human only lyrics.]
~ vocals_whalesong = "Human"
--
-
-> LOCKED_SONG
= GUITARIST_STEM_LOCK
+ [Keep it.]
+ [Change it.]
++ [People pleasing guitar solo!]
~ guitar_whalesong = "Human"
++ [Wail for the whales guitar.]
~ guitar_whalesong = "Whaleish"
--
-
-> LOCKED_SONG
= BASSIST_STEM_LOCK
+ [Keep it.]
+ [Change it.]
++ [Whaley deep bass.]
~ bass_whalesong = "Whaleish"
++ [People pleasing pop bass.]
~ bass_whalesong = "Human"
--
-
-> LOCKED_SONG
= KEYS_STEM_LOCK
+ [Keep it.]
+ [Change it!]
++ [Whaley harmonics.]
~ keys_whalesong = "Whaleish"
++ [Pop chords.]
~ keys_whalesong = "Human"
--
-
-> LOCKED_SONG
= LOCKED_SONG
SINGER: Well, that's a wrap on practice. This weekend, {band_name}'s first song will debut at _Float the Vote!_
-> PERFORMANCE_WHALESONG
Reference in New Issue View Git Blame Copy Permalink