372 lines
17 KiB
Plaintext
372 lines
17 KiB
Plaintext
-> POST_PERFORM_WHALESONG
|
|
|
|
=== POST_PERFORM_WHALESONG ===
|
|
#Environment: van_exterior
|
|
|
|
#AddChar: Singer, Pose: neutral
|
|
#AddChar: Guitarist, Pose: neutral
|
|
#AddChar: Bassist, Pose: neutral
|
|
#AddChar: Keyboardist, Pose: neutral
|
|
#AddChar: Drummer, Pose: neutral
|
|
|
|
//MK: I'm not convinced that Singer would speak first if they'd switched lyrics, I gave this to Akai. If we're saying that the performance always goes well in the room, Singer could start this because they want to say "see? It worked!" So, I gave this to Akai for the moment. //HJ: Agreed!
|
|
|
|
DRUMMER: LET'S GET WASTED!
|
|
|
|
SINGER: I think Akai means "great first show!"
|
|
|
|
{
|
|
- (song_stance_L1 == "Human") && (vocals_whalesong == "Whaleish"):
|
|
GUITARIST: Was it, though? We agreed you wouldn't sing in Whaleish, and you did it anyway.
|
|
-> DISSENT_STANCE_WHALEISH
|
|
- (song_stance_L1 == "Whaleish") && (vocals_whalesong == "Human"):
|
|
KEYBOARDIST: No it wasn't. You were supposed to sing in Whaleish! Like we agreed!
|
|
-> DISSENT_STANCE_HUMAN
|
|
- else:
|
|
DRUMMER: I would never say you were great. But the crowd did love it. //Ha!
|
|
~ band_unity++
|
|
{WHALESONG_JAM.DISSENTER_SINGER: -> DISSENTER_STANCE_SWITCH | -> BAND_VISION_CHECK}
|
|
}
|
|
|
|
= DISSENTER_STANCE_SWITCH
|
|
BASSIST: Hey, {name_singer}. Thanks for singing the lyrics we agreed on.
|
|
BASSIST: Even if you didn't want to.
|
|
-> BAND_VISION_CHECK
|
|
|
|
= DISSENT_STANCE_WHALEISH
|
|
~ band_unity-- //NOTE: Dissent automatically knocks down band unity. Only the players' choices can bring it back up, or knock it down farther.
|
|
BASSIST: So, {name_singer}. Any reaction? You know... to your band not trusting you?
|
|
//NOTE: When a player has PRIVATE choices, the other players just see " . . . " above their heads until they make their choice. Only then do the other players see the line. I, at least, think this is a good example of Private Choices being the best option, rather than Public Choices.
|
|
|
|
+ [SINGER: I know I made the right choice.] #PRIVATE
|
|
SINGER: I know I went back on what I said. But I have to sing what I believe in.
|
|
SINGER: And it worked. No people walked out. And the whales loved it.
|
|
|
|
+ [SINGER: I shouldn't have done that.] #PRIVATE
|
|
SINGER: I did what I believed in most, but that's not the point.
|
|
SINGER: We agreed. And we need to be able to trust each other. I'm sorry.
|
|
-
|
|
|
|
~ temp mood = 0
|
|
|
|
+ [BASSIST: I can accept that.] #PRIVATE
|
|
BASSIST: We all think this sucks, but I'm good to put it behind us.
|
|
~ mood++
|
|
|
|
+ [BASSIST: {name_singer} is full of shit.] #PRIVATE
|
|
BASSIST: I'm not telling anyone else how to feel. But, I can't overlook this.
|
|
~ mood--
|
|
-
|
|
|
|
BASSIST: Can you, {name_guitarist}?
|
|
|
|
+ [GUITARIST: {name_singer} did what they wanted. I respect that.] #PRIVATE
|
|
GUITARIST: Let's just move on. It's not like we bombed.
|
|
~ mood++
|
|
|
|
+ [GUITARIST: I'm not happy. I must have looked ridiculous.] #PRIVATE
|
|
GUITARIST: We could have looked like fools. That should matter to us.
|
|
~ mood--
|
|
-
|
|
|
|
/*
|
|
HJ: Because Keys is less confrontational, I thought we'd make Keys the reaction character. So Keys doesn't get a secret choice in this scene, but how the others responded above (tracked by temp variable) will influence Keys' response. If it's a mood "tie" b/w Bassist and Guitarist, Keys will break it towards the positive and add a +1 to band unity, effectively nullifying the -1 at the start of this stitch. If both Bassist and Guitarist responded positively to Singer, Keys adds to that. +2 to unity! But if Guitarist and Bassist were both negative, take -2 off unity.
|
|
|
|
NOTE: The point of using the temp variable instead of adding/subtracting band_unity on Bassist/Guitar's responses is that we can't be sure what value band_unity started at. Whereas we know the temp variable started at 0.
|
|
*/
|
|
|
|
{
|
|
- mood == 0: //Bassist and Guitarist had opposite responses and cancelled each other out
|
|
KEYBOARDIST: The whales are happy...so, maybe we can just hug it out.
|
|
GUITARIST: Way to find the bright side, {name_keyboardist}. Not sold on the hug part, though.
|
|
BASSIST: No one try to hug me. But, yeah. I'm not ready to break up the band.
|
|
~ band_unity +=1
|
|
- mood == 2: //mood is positive
|
|
KEYBOARDIST: Great work, everbody! I love resolutions!
|
|
~ band_unity +=2
|
|
- else: //mood is negative
|
|
KEYBOARDIST: Everyone has a right to their feelings. But these ones are too negative for me.
|
|
~ band_unity -=2
|
|
}
|
|
|
|
-> BAND_UNITY_CHECK
|
|
|
|
= DISSENT_STANCE_HUMAN
|
|
~ band_unity--
|
|
KEYBOARDIST: You said you'd sing for the whales. Why didn't you sing for the whales?!
|
|
|
|
+ [SINGER: Because I was afraid. And I'm afraid to admit that.] #PRIVATE
|
|
SINGER: I just...realized that I shouldn't.
|
|
|
|
+ [SINGER: I made the right decision.] #PRIVATE
|
|
SINGER: It was better to focus on the human audience. The whales already get it.
|
|
-
|
|
|
|
+ [GUITARIST: This was the best choice.] #PRIVATE
|
|
GUITARIST: {name_singer} did the right thing. It's not like Whales would come to our next show, anyway.
|
|
GUITARIST: And we didn't have to compete with Whale sounds to be heard.
|
|
~ band_unity++
|
|
|
|
+ [GUITARIST: The kid's right. {name_singer} has to stick to the plan.] #PRIVATE
|
|
GUITARIST: I'm surprised, {name_singer}. You've always been about open communication.
|
|
GUITARIST: Unless you tricked me with that, too.
|
|
~ band_unity--
|
|
-
|
|
|
|
+ [BASSIST: I gotta stand up for {name_singer}.] #PRIVATE
|
|
BASSIST: We're all pissed off. But {name_singer}'s the one up front.
|
|
BASSIST: You can't sing something you don't believe in.
|
|
~ band_unity++
|
|
|
|
+ [BASSIST: {name_singer} really messed up. I can't let this go.] #PRIVATE
|
|
BASSIST: I really respected the guts it took to sing in Whaleish...
|
|
BASSIST: But I guess you didn't really have them. Now we know. //ouch!
|
|
~ band_unity--
|
|
-
|
|
|
|
-> BAND_UNITY_CHECK
|
|
|
|
//NOTE: If band went into the performance with the highest unity score of +4 , but made all the negative choices in these dissenter stitches, the highest score they could have now is +1 , which is why that is the number we're checking against in the stitch below...
|
|
|
|
= BAND_UNITY_CHECK
|
|
|
|
{band_unity <= 1:
|
|
DRUMMER: Well, I didn't think you'd break up after your first song.
|
|
DRUMMER: But you're close. Very close. //MK: I wonder about talking about band unity in a way that highlights its metric nature. But maybe this line doesn't work. //HJ: Hmm... I'm not sure. Let's see how it plays when we have more scripts. I'll leave this comment here so we remember to think about it again.
|
|
- else:
|
|
DRUMMER: Congratulations! You've survived your first band betrayal. //ha!
|
|
|
|
KEYBOARDIST: That's the power of positivity! //haha!
|
|
}
|
|
|
|
+ [SINGER: I'm glad that worked out.] #PRIVATE
|
|
+ [SINGER: I shouldn't have betrayed my bandmates.] #PRIVATE
|
|
-
|
|
-> BAND_VISION_CHECK
|
|
|
|
= BAND_VISION_CHECK
|
|
|
|
KEYBOARDIST: Oh, wow! We already have a review! //MK: Can/should we attribute the review to someone? This city's version of NOW Magazine? //HJ: That's a good idea! It'll also give Art something to work with when they're coming up with the visuals for this scene.
|
|
|
|
{vocals_whalesong == "Whaleish":
|
|
KEYBOARDIST: "{band_name} Rocks the Boat at Float the Vote!"
|
|
- else:
|
|
KEYBOARDIST: "{band_name} Sets Sail at Float the Vote!"
|
|
}
|
|
|
|
BASSIST: Gross. I hope the writing gets better from there. //haha!
|
|
|
|
KEYBOARDIST: If you interrupt, you'll never know. //you tell 'em, Keys!
|
|
|
|
BASSIST: (laughs) Okay, I'm ready to listen.
|
|
|
|
KEYBOARDIST: "The pro-vote message has been delivered loud and clear at this festival,
|
|
|
|
{vocals_whalesong == "Whaleish":
|
|
KEYBOARDIST: ...but only {band_name} has done it in Whale song!"
|
|
KEYBOARDIST: "These Rebels even earned some tail-slaps of approval from the Whales in attendance!"
|
|
- else:
|
|
KEYBOARDIST: ...but no one has been louder or clearer than {band_name}."
|
|
KEYBOARDIST: "The Whales have the vote, and now the People may have their band." //MK: really struggling with a way to say "band of the people" that doesn't sound ridiculous. I'm sure these will both change. I'd like them to. //HJ: You gave yourself a pass with Bassist's comment on Line 157! What you have now is clear, so the line is doing its job.
|
|
}
|
|
|
|
+ What a great review!
|
|
+ The writing did NOT get better[.]. But it's still an awesome review! //HJ: This is a fun trick! The square brackets around the period signal that that is where the choice ends. But once selected, both sentences appear! This is a handy way to have short choices that naturally become longer responses. //MK: Yeah, that's cool.
|
|
-
|
|
|
|
SINGER: So, our first song is a hit?
|
|
|
|
DRUMMER: It's more than that...
|
|
{vocals_whalesong == "Whaleish":
|
|
DRUMMER: Human enrollment in Whaleish classes has spiked, and whales have already been heard singing the song a thousand miles away.
|
|
- else:
|
|
DRUMMER: There are calls to adopt it as an official anthem of inter-species democracy.
|
|
}
|
|
GUITAR: Yeah, I'd say that qualifies as "a hit."
|
|
|
|
-> FAN_REACTIONS
|
|
|
|
= FAN_REACTIONS
|
|
#PlaySFX: Akai_excited
|
|
DRUMMER: THERE IS NO ENCORE! //haha!
|
|
DRUMMER: (sigh) Time to go. I'm not programmed to pack up the gear, by the way.
|
|
//NOTE: The team doesn't have time to design a social media interface for the CMF demo, so what I've done here is just split the characters out into their own screens and we'll write this as if they're on their devices reading the comments.
|
|
|
|
#SPLITFLOW
|
|
{
|
|
- char_singer:
|
|
You _should_ pack up, but you want to see what else people said...
|
|
{vocals_whalesong == "Whaleish": -> SINGER_SOCIALS_WHALEISH | -> SINGER_SOCIALS_HUMAN }
|
|
|
|
- char_guitarist:
|
|
You ignore Akai and scroll through the fan comments and critic reviews...
|
|
{
|
|
- keys_whalesong == "Whaleish": //If Keys played whaleish harmonics
|
|
-> GUITAR_SOCIALS_KEYS
|
|
- vocals_whalesong == "Whaleish":
|
|
-> GUITARIST_SOCIALS_WHALEISH
|
|
- else:
|
|
-> GUITARIST_SOCIALS_HUMAN
|
|
}
|
|
|
|
- char_bassist:
|
|
You start packing gear with one hand while scrolling with the other...
|
|
-> BASSIST_SOCIALS //NOTE: Doesn't matter what the lyrics are, Bassist's social messages are the same.
|
|
|
|
- char_keyboardist:
|
|
You _should_ pack up, but you're too excited! So you keep scrolling...
|
|
{
|
|
- keys_whalesong == "Whaleish": //If Keys played whaleish harmonics
|
|
-> KEYS_SOCIALS_WHALE_INVITE
|
|
- vocals_whalesong == "Human": //If Keys didn't play whaleish harmonics and lyrics were human only
|
|
-> KEYS_SOCIALS_HUMAN
|
|
- else: //Keys didn't play whaleish harmonics but the lyrics were in Whaleish
|
|
-> KEYS_SOCIALS_WHALEISH
|
|
}
|
|
}
|
|
|
|
= SINGER_SOCIALS_WHALEISH
|
|
SINGER: "The Cetacean Consulary Pod"? That's... the Whale ambassador's office!
|
|
SINGER: "Voice {name_singer} of songpod {band_name}. We thank you for singing to us and of us..."
|
|
SINGER: "We will smooth your tones, and carry your song always." My tones? I guess my grammar wasn't perfect.
|
|
|
|
+ [You're glad you took a chance and sang Whaleish.]
|
|
SINGER: "You honour me, and I am grateful. Humans welcome your voice to the chorus".
|
|
SINGER: I think that's the right thing to say.
|
|
|
|
+ [You feel terrible because you screwed up the grammar.]
|
|
SINGER: "I'm very sorry if I've given offense. I did my best to sing in your language, and I hope you can forgive my mistakes."
|
|
SINGER: I should have known I wouldn't get it right.
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= SINGER_SOCIALS_HUMAN
|
|
SINGER: "Another song written from the Whale perspective, but sung in a human voice."
|
|
SINGER: "If anyone can sing in Whaleish, it's {name_singer}. I expected more."
|
|
|
|
+ [Defend human-only lyrics.]
|
|
SINGER: "We made the choice to focus solely on the human audience because that's who needs the message. We hope you'll hear the next one!"
|
|
|
|
+ [Apologize for not singing in Whaleish.]
|
|
SINGER: "I ultimately decided not to sing in Whaleish, but I should have believed in myself enough to try. I'm sorry if I let anyone down."
|
|
|
|
+ [Don't respond.]
|
|
SINGER: Everyone has an opinion. And that's that.
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= GUITAR_SOCIALS_KEYS
|
|
GUITARIST: "Whale Chorus invites {name_keyboardist} of {band_name} to ocean jam"?
|
|
GUITARIST: What? No invite for {name_guitarist}, also of {band_name}? Next...
|
|
|
|
{vocals_whalesong == "Whaleish": -> GUITARIST_SOCIALS_WHALEISH | -> GUITARIST_SOCIALS_HUMAN }
|
|
|
|
= GUITARIST_SOCIALS_WHALEISH
|
|
GUITARIST: "{name_singer} is, like, a pan-species vocalist!"
|
|
GUITARIST: "{name_singer} duet with Whale {name_singer}! Make it happen!"
|
|
GUITARIST: ...there's nothing. Nothing about "wicked guitar". I knew it.
|
|
|
|
GUITARIST: Fine, the song was a hit. But, it's like I wasn't even there.
|
|
|
|
+ [Resent Singer for stealing spotlight.]
|
|
GUITARIST: {name_singer} should have just done this a capella.
|
|
~ arc_guitarist = "egocentric"
|
|
|
|
+ [Concede that Whaleish lyrics were best for the song.]
|
|
GUITARIST: The Whaleish did get noticed. Which got {band_name} noticed.
|
|
~ arc_guitarist = "humbled"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= GUITARIST_SOCIALS_HUMAN
|
|
GUITARIST: "{name_guitarist} is back!" Hell yeah, I am.
|
|
GUITARIST: "I recognized {name_guitarist} from the first chord! Was anyone else even playing?"
|
|
|
|
+ {guitar_whalesong == "Whaleish"}[Revel in the attention!]
|
|
GUITARIST: The comeback in ON, baby. The band's gotta see my value, now.
|
|
~ arc_guitarist = "egocentric"
|
|
|
|
+ {guitar_whalesong == "Human"}[Gloat about rocking solo!]
|
|
GUITARIST: Nice. If {band_name} wants a hit, it needs a {name_guitarist} solo.
|
|
~ arc_guitarist = "egocentric"
|
|
|
|
+ [Concede it was the right choice to debut with a strong message.]
|
|
GUITARIST: Well... blistering guitar aside... we had the right message.
|
|
~ arc_guitarist = "humbled"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= BASSIST_SOCIALS
|
|
BASSIST: I'm not gonna read all this...
|
|
BASSIST: Lotta positive emojis, though. That's good.
|
|
BASSIST: "{band_name} got to me. I'm listening, for real". Huh.
|
|
|
|
+ [You still don't think anything will change.]
|
|
BASSIST: People always have something to say. And... that's it.
|
|
~ arc_bassist = "cynical"
|
|
|
|
+ [You have hope that humanity will do better.]
|
|
BASSIST: Well... maybe the Whale vote can wake some people up.
|
|
~ arc_bassist = "hopeful"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= KEYS_SOCIALS_WHALE_INVITE
|
|
KEYBOARDIST: OH MY GOD.
|
|
KEYBOARDIST: I'm invited to the Humpback Calving Season Jam?! I can play whale synth!
|
|
KEYBOARDIST: Wait... "Why no whale/guitar collab"? Why would {name_guitarist} leave that comment? I should respond.
|
|
|
|
+ [Hype {name_guitarist} up!]
|
|
KEYBOARDIST: "You rock, {name_guitarist}. I know they love you!"
|
|
~ arc_keyboardist = "chearlead"
|
|
|
|
+ [Correct {name_guitarist}'s negative attitude.]
|
|
KEYBOARDIST: "None of that! The sea is cold enough without negative energy!"
|
|
~ arc_keyboardist = "police"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= KEYS_SOCIALS_HUMAN
|
|
KEYBOARDIST: Oh, no...
|
|
KEYBOARDIST: "We know that our song is not easily sung by humans, even {name_singer}, but the effort would have meant much".
|
|
KEYBOARDIST: The Whales are sad.
|
|
|
|
+ [Agree, without blaming {name_singer}.]
|
|
KEYBOARDIST: "We hear you. But it was a {band_name} choice."
|
|
~ arc_keyboardist = "chearlead"
|
|
|
|
+ [Agree, and blame it on Singer.]
|
|
KEYBOARDIST: "We're so sorry! Some of us were willing to try. But not all."
|
|
KEYBOARDIST: "Right, {name_singer}?"
|
|
~ arc_keyboardist = "police"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= KEYS_SOCIALS_WHALEISH
|
|
KEYBOARDIST: Everyone is so happy! I knew they'd love Whale Song.
|
|
KEYBOARDIST: Whales are on social. Maybe they hired someone with thumbs.
|
|
KEYBOARDIST: Inspiring people is... so inspiring! I'm totally signing up for Whaleish lessons!
|
|
|
|
+ [Invite your bandmates to join you.]
|
|
KEYBOARDIST: "Hey, {band_name}! Let's go back to school together! We'll be Whaleish lunch pals!"
|
|
~ arc_keyboardist = "chearlead"
|
|
|
|
+ [Sign up your bandmates without asking them.]
|
|
KEYBOARDIST: I'll just sign them up. They'll be into it after the first class.
|
|
~ arc_keyboardist = "police"
|
|
-
|
|
-> LEAVE_VENUE
|
|
|
|
= LEAVE_VENUE
|
|
#REJOIN
|
|
DRUMMER: WOOOO! AKAI OUT!
|
|
DRUMMER: Seriously, though. I'm not packing the gear.
|
|
|
|
KEYBOARDIST: Okay, {name_singer}, {name_guitarist} and {name_bassist}, time for us to "band together" and pack up!
|
|
|
|
+ Everyone gives {name_keyboardist}'s pun a resounding "BOOOOO"[.] and starts packing.
|
|
+ A couple of you chuckle at {name_keyboardist}, assuring further puns[.] before getting to work packing up.
|
|
-
|
|
#Transition: packing_up
|
|
//HJ: ^^I totally just made that up. We're a long way from transitions, but one of packing up the van would be super handy! And could be used after every performance.
|
|
-> OUTCOME_WHALESONG |