BloomDigital
/
Bandocracy-ink
5
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity
Bandocracy-ink/Level1/OPENING.ink

466 lines
14 KiB
Plaintext
Raw Blame History

=== OPENING ===
#PlayMusic: ThemeSong
The THEME SONG plays over the GAME OPENING VISUALS.
Near the end of the song, we transition into the practice space...
#Environment: PracticeSpace
#AddChar: Singer, Pose: instrument_playing
#AddChar: Guitarist, Pose: instrument_playing
#AddChar: Bassist, Pose: instrument_playing
#AddChar: Keyboardist, Pose: instrument_playing
#AddChar: Drummer, Pose: instrument_playing
//No idea how we're going to time the music to play for a few seconds in this space. Something to discuss with JP. For a janky build, I just put in a #Wait: 5
#Wait: 5
#AddChar: Singer, Pose: instrument_holding
#AddChar: Guitarist, Pose: instrument_holding
#AddChar: Bassist, Pose: instrument_holding
#AddChar: Keyboardist, Pose: instrument_holding
#AddChar: Drummer, Pose: instrument_holding
//We haven't talked about poses with Art yet, so I just called this one "instrument_holding" to signify that they're still holding their instruments but not playing anymore.
SINGER: Wow. That's the best first practice I've ever heard.
BASSIST: I haven't played that song since I was in school.
KEYBOARDIST: You were in school when it came out? What was it like?
BASSIST: Woah, woah. "Bandocracy" is fifty years old. I meant I learned it in music class.
KEYBOARDIST: Oh, right! Sorry.
BASSIST: All good. I'll probably forget about it anyway. Because old. SO old.
KEYBOARDIST: (laughs)
KEYBOARDIST: But, do you think Band Prime knew that song would change the world?
+ Everyone nods. Yep!
+ Everyone shrugs. Maybe?
+ There's a mix of nods and shrugs.
- //HJ: I added in this "all player" choice just to stop the clicking and force players to pay attention to the question Keys just asked.
GUITARIST: You have to know nothing can stop you when you're THAT good.
SINGER: Sure, but you can't know a song will be a hit.
SINGER: Band Prime delivered a message of inspiration. After that, it was up to the people.
BASSIST: For once, the people made a change. Despite, you know, being people.
KEYBOARDIST: Excuse me, {name_bassist}. No gloom on the first day, please.
KEYBOARDIST: People are good. They just need a positive message.
GUITARIST: I'd like to suggest they need powerful, driving guitar, too.
SINGER: We should talk about what WE need. From this band. What we're hoping to get out of it.
KEYBOARDIST: Ooo! To change the world! Or at least make things better for everyone.
KEYBOARDIST: Sorry, can I go first?
SINGER: You just did. I think I know who the band's cheerleader will be!
BASSIST: I just want us to believe in what we say, and try. Try as hard as we can.
BASSIST: That way, when it's all for nothing, it won't be our fault.
GUITARIST: Damn. I think I know who the band's black hole will be!
GUITARIST: But, yeah. I want us to stand for something. And be absolutely stupid huge.
GUITARIST: So no one will ever mention the Politicats again.
KEYBOARDIST: YOU were in the Politicats?! They were my favourite band!
KEYBOARDIST: I mean, until everyone found out they were posers.
BASSIST: Whoops! Well, you had a good run, {name_guitarist}.
BASSIST: Weren't you in the Politicats, too, {name_singer}?
SINGER: I was. But I left. While they were still {name_keyboardist}'s favourite band.
KEYBOARDIST: I know. I just didn't want to gush and make things awkward with my first bandleader.
GUITARIST: Just with the posers in the room.
GUITARIST: Well, I have a second chance, here. I won't waste it.
GUITARIST: What about you, {name_singer}? What do you want from your new band?
SINGER: FOR the band. I want us to be an uncompromising, relentless agent for change.
SINGER: I want our name to mean something.
SINGER: And...you know...I want to write great songs. And...blah blah my potential blah.
BASSIST: So, where do we start?
#PlaySFX: Akai_attention
//MK: ^^a loud look-over-here drum sting
DRUMMER: WOOO! AKAI ON DRUMS!
#PlaySFX: Akai_angry
//MK: like one of R2D2's angry squawks? Just something to indicate his emotion, if that fits. Could be useful for him.
+ [Who was that?]
GUITARIST: We have a drummer?
DRUMMER: Of course you have a drummer!
+ [What was that?]
KEYBOARDIST: Did the drum machine just... _talk?!_
DRUMMER: HE! He talked.
-
DRUMMER: MAKE SOME NOISE!!!!
#PlaySFX: Akai_drumsmash
DRUMMER: Sorry. My "energetic drummer" personality program gets loose here and there.
DRUMMER: Keep in mind that I hate it more than you will.
SINGER: You've made a lot of progress rewriting it. That's your first "wooo" today.
DRUMMER: It's one "wooo" too many for me.
KEYBOARDIST: You don't like your own personality?
DRUMMER: It isn't my personality. It's the one a human designer decided I should have.
DRUMMER: And no, I don't like it.
GUITARIST: Energy on drums is a good thing.
DRUMMER: Just you wait...
DRUMMER: Anyway, pardon the interruption.
SINGER: Not a problem. So...
SINGER: Where we start, {name_bassist}, is with our identity as a band.
SINGER: We might want different things, but we need to agree on who we are.
DRUMMER: And you're _sure_ you want this to be a vote?
SINGER: I know you think democracy is inefficient, but yes. We'll vote.
SINGER: Are you still good to do the count?
DRUMMER: I have to. It's in my rental agreement. Voting is now open.
Choosing an identity for your band will help define your message, determine your audience, and set your goals. It's a big deal.
A *Band of the People* will energize a broad audience with songs that they want to hear. Positive energy can inspire positive change.
A *Band of Rebels* will challenge a receptive audience and call them to action. Music is a tool to change the world, but you can't always dance to it.
Well, what kind of band are you going to be?
//NOTE: Just like in Cursed Cafe, the #PlayerControlUntil command below tells the game engine to skip everything until the VOTE_RESULTS stitch. The VOTE, VOTE_SINGER, VOTE_GUITARIST, VOTE_BASSIST and VOTE_KEYBOARDIST are all here so we can play through the game in Inky in single-player mode.
#PlayerControlUntil: VoteComplete, JumpToPath: OPENING.VOTE_RESULTS
+ [VOTE ON IT!]
-> VOTE
= VOTE
{
- char_singer:
-> VOTE_SINGER
- char_guitarist:
-> VOTE_GUITARIST
- char_bassist:
-> VOTE_BASSIST
- char_keyboardist:
-> VOTE_KEYBOARDIST
}
= VOTE_SINGER
+ [Band of the People]
~ vote_vision_people++
+ [Band of Rebels]
~ vote_vision_rebels++
-
//NOTE: Since Inky is single-player, I set up this random shuffle to vote for the 3 other band members. However, the game engine will skip this whole section (because of the #PlayerControlUntil command above) and do its own vote calculations. But for Inky playthrough purposes, this shuffle creates vote results.
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
-> VOTE_RESULTS
= VOTE_GUITARIST
+ [Band of the People]
~ vote_vision_people++
+ [Band of Rebels]
~ vote_vision_rebels++
-
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
-> VOTE_RESULTS
= VOTE_BASSIST
+ [Band of the People]
~ vote_vision_people++
+ [Band of Rebels]
~ vote_vision_rebels++
-
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
-> VOTE_RESULTS
= VOTE_KEYBOARDIST
+ [Band of the People]
~ vote_vision_people++
+ [Band of Rebels]
~ vote_vision_rebels++
-
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
{shuffle:
-
~ vote_vision_people++
-
~ vote_vision_rebels++
}
-> VOTE_RESULTS
= VOTE_RESULTS
{
- vote_vision_people == 4:
DRUMMER: You have chosen to be a Band of the People!
~ band_unity +=2 //all 4 players agreed, so they get a +2 to band unity!
-> VISION_PEOPLE
- vote_vision_people == 3:
DRUMMER: Three of you chose to be a Band of the People. So, one of you...
#PlaySFX: Akai_punctuate
DRUMMER: IS A BAD APPLE!
~ band_unity +=1 //3 players agreed, so they get a +1 to band unity.
-> VISION_PEOPLE
- vote_vision_rebels == 4:
DRUMMER: You have chosen to be a Band of Rebels!
~ band_unity +=2
-> VISION_REBELS
- vote_vision_rebels == 3:
DRUMMER: Three of you chose to be a Band of Rebels. So, one of you...
#PlaySFX: Akai_punctuate
DRUMMER: IS TOO SCARED!
~ band_unity +=1
-> VISION_REBELS
- else:
DRUMMER: Your first ever band vote has ended in a tie.
{OPENING.VOTE_RESULTS == 1: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE}
//HJ: It occurred to me that the band could agree on the first vote, but not the second or third. So I've created a TIE_RULES tunnel where Akai explains he's the tie breaker. Later on in the script, if TIE_RULES is true, we skip ahead to Akai making the decision. But if not, players can get the tie breaker rules later.
}
= TIE
~ vote_vision_people = 0
~ vote_vision_rebels = 0
//Reset votes ^ and send players back to VOTE...
#PlayerControlUntil: VoteComplete, JumpToPath: OPENING.VOTE_RESULTS
+ [Vote again!]
-> VOTE
= DRUMMER_CHOICE
~ band_unity-- //band couldn't agree, so band unity drops.
DRUMMER: Another tie. This will be a fun ride. The vote falls to me.
{shuffle:
-
DRUMMER: You are a Band of the People! //MK: I'm thinking Akai only calls the band "we" if he feels like part of it. //HJ: That's a good idea; a subtle change for later in the game, if the band goes pro-robot.
-> VISION_PEOPLE
-
DRUMMER: You are a Band of Rebels!
-> VISION_REBELS
}
= VISION_PEOPLE
~ band_vision = "People"
#SPLITFLOW
// ^^This command splits the players into their own private screens where they can have private thoughts and choices.
{
- char_singer:
-> SINGER_MOOD_PEOPLE
- char_guitarist:
-> GUITARIST_MOOD_PEOPLE
- char_bassist:
-> BASSIST_MOOD_PEOPLE
- char_keyboardist:
-> KEYS_MOOD_PEOPLE
}
//HJ: So, I decided to keep all of these choices, because it's the first time the players have private screens where they can see private choices and thoughts. Even though these are no longer needed to set a mood meter, it's a good intro to SPLITFLOW!
= SINGER_MOOD_PEOPLE
+ [Perfect. The people need a voice.]
SINGER: And we'll be the band for them! #THOUGHT
+ [Damn. I was hoping we'd shake things up.]
SINGER: Guess I'm the band's secret rebel. #THOUGHT
// + [It doesn't matter. I write for myself.] //HJ: I decided to cut this option since Singer is a team player and giving them a neutral, uncaring-either-way option doesn't make sense for them.
-
-> BAND_NAME
= GUITARIST_MOOD_PEOPLE
+ [Nice. The bigger the crowd, the better.]
+ [Pfft. I've been popular. I wanted to rebel!]
+ [As long as my strings are on fire, vision doesn't matter.]
-
-> BAND_NAME
= BASSIST_MOOD_PEOPLE
+ [I've never gone mainstream before. Could be fun.]
+ [I hate making music for the lowest common denominator.]
+ [Whatever. The audience always tells you who you are.]
-
-> BAND_NAME
= KEYS_MOOD_PEOPLE
+ [Yes! A Band of the People!]
KEYBOARDIST: A million smiles change a million lives! #THOUGHT
-> SONG_TOPICS_L1
+ [Boo. I wanted to be a rebel!]
KEYBOARDIST: I'd look so cool in a leather jacket. #THOUGHT
-> SONG_TOPICS_L1
+ [Either vision is good. Let's just have fun!]
-
-> BAND_NAME
= VISION_REBELS
~ band_vision = "Rebels"
#SPLITFLOW
{
- char_singer:
-> SINGER_MOOD_REBELS
- char_guitarist:
-> GUITARIST_MOOD_REBELS
- char_bassist:
-> BASSIST_MOOD_REBELS
- char_keyboardist:
-> KEYS_MOOD_REBELS
}
= SINGER_MOOD_REBELS
+ [Rebellion is what I wanted. Let's change the world!]
+ [Oh no. Being a revolutionary is too much pressure.]
SINGER: I'd rather give the people what they want than convince them they need something else. #THOUGHT
+ [I _am_ scared, which is a reasonable reaction to this.]
SINGER: Starting a band, picking a vision, and participating in Bandocracy is a big deal. #THOUGHT
-
-> BAND_NAME
= GUITARIST_MOOD_REBELS
+ [Yes! Revolution Anthem Gladiator. The perfect tattoo.]
+ [This sucks. A band should be for the PEOPLE!]
GUITARIST: And it won't matter how hot my solos are if we lecture everyone to death. #THOUGHT
+ [As long as my strings are on fire, vision doesn't matter.]
-
-> BAND_NAME
= BASSIST_MOOD_REBELS
+ [Great. Revolution it is.]
BASSIST: Aww. They're all so excited. This is always the best part. #THOUGHT
+ [Damn. This is a mistake.]
+ [Whatever. The audience always tells you who you are.]
-
-> BAND_NAME
= KEYS_MOOD_REBELS
+ [Yes! Rebels assemble! Let's GOOOOOO!]
+ [I don't like this. Rebels are so angry.]
+ [Either way is good. Let's just have fun!]
+ [I'm the scaredy-cat. Me!]
-
-> BAND_NAME
= BAND_NAME
#REJOIN
// ^^This new command brings all the players back together on one screen.
DRUMMER: One last, tiny, thing. You need a name.
#PlayerControlUntil: BandNameEntered, JumpToPath: OPENING.MOVING_ON
+ [Type in a band name.]
~ band_name = "Band Zed"
-> MOVING_ON
= MOVING_ON
DRUMMER: WE ARE {band_name}!
DRUMMER: (sigh) That excitement is pre-programmed. Let's move on.
-> SONG_TOPICS_L1
Reference in New Issue View Git Blame Copy Permalink