Bandocracy-ink/MAIN_Bandocracy.ink

-> ONBOARDING

INCLUDE Level1/OPENING.ink
INCLUDE Level1/TIE_RULES.ink
INCLUDE Level1/SONG_TOPICS_L1.ink

INCLUDE Level1/PRACTICE_WHALESONG.ink
INCLUDE Level1/PERFORMANCE_WHALESONG.ink
INCLUDE Level1/POST_PERFORM_WHALESONG.ink
INCLUDE Level1/OUTCOME_WHALESONG.ink

INCLUDE Level1/PRACTICE_MOODTATTOOS.ink
INCLUDE Level1/PERFORMANCE_MOODTATTOOS.ink
INCLUDE Level1/POST_PERFORM_MOODTATTOOS.ink
INCLUDE Level1/OUTCOME_MOODTATTOOS.ink

INCLUDE Level2/SONG_TOPICS_L2.ink




// *** CHARACTER VARIABLES ***

    //ONBOARDING - for Single-Player mode; false unless selected
VAR char_singer = false
VAR char_guitarist = false
VAR char_bassist = false
VAR char_keyboardist = false

VAR name_singer = ""
VAR name_guitarist = ""
VAR name_bassist = ""
VAR name_keyboardist = ""

VAR pronouns_singer = "" // femme, masc, enby
VAR pronouns_guitarist = ""
VAR pronouns_bassist = ""
VAR pronouns_keyboardist = ""

VAR arc_singer = ""
VAR arc_guitarist = ""
VAR arc_bassist = ""
VAR arc_keyboardist = ""


// *** BAND VARIABLES ***

VAR band_name = ""
VAR band_unity = 0
VAR band_vision = "" // "People", "Rebels"
VAR band_stance_L1 = "" // "People", "Rebels" - exact same as vision, so we can see if these two variables are the same or not, to reflect whether the band has stuck to their vision or deviated from it. 
VAR song_stance_L1 = "" // "Whaleish", "Human", "Pro-Tattoo", "Anti-Tattoo" - so we can check if they're equal to the stems chosen
VAR band_stance_L2 = ""
VAR band_stance_L3 = "" //By L4 we should be able to do some math using these variables to determine which stance the band's fans and critics expect them to take on the final song. And if it doesn't match, fans and critics will react accordingly. 


// *** SONGS LIST ***

LIST songs = WhaleSong, MoodTattoo
/*I decided to make a list to track the songs, rather than having TRUE/FALSE variables for every song. 
For this demo, we have 2 songs. Neither song is "ON" the list yet, but each is available to be put on the list. Code-wise, round brackets around the song names would mean they are already "ON" the list. To add a song to this list, use this command:
    ~ songs += WhaleSong
*/


// *** VOTING VARIABLES ***

VAR vote_vision_people = 0
VAR vote_vision_rebels = 0

//SONG TOPICS
VAR vote_songtopic_whales = 0
VAR vote_songtopic_tattoos = 0

//SONG STANCES
VAR vote_songstance_whaleish = 0
VAR vote_songstance_human = 0
VAR vote_songstance_protattoo = 0 
VAR vote_songstance_antitattoo = 0 

//SONG STEMS (only drum stems are voted on; PCs choose their own stems)
VAR vote_whalesong_drums_human = 0
VAR vote_whalesong_drums_whaleish = 0
VAR vote_moodtattoo_drums_anti = 0 
VAR vote_moodtattoo_drums_pro = 0 


// *** MUSIC VARIABLES ***

//All whalesong music variables will get set to "Whaleish" or "Human".
VAR drums_whalesong = "" 
VAR vocals_whalesong = "" 
VAR guitar_whalesong = "" 
VAR keys_whalesong = "" 
VAR bass_whalesong = "" 
//All moodtattoo variables will get set to "Pro" or "Anti".
VAR drums_moodtattoo = "" 
VAR vocals_moodtattoo = "" 
VAR guitar_moodtattoo = "" 
VAR keys_moodtattoo = "" 
VAR bass_moodtattoo = ""

//This counts each player who picks "pop" or "whaleish".  
VAR whalesong_human_count = 0
VAR whalesong_whaleish_count = 0
//There must be a more elegant way to do this without resorting to numbers, which is what the demo originally did - each type of stem was assigned a number, and through functions/back-end code, the game engine could tell how many players had chosen pop or whaleish stems. I'll think on this more when I outline Whale Song.


// *** STORY VARIABLES ***
VAR band_knows_about_singer_mom = false 
VAR its_personal = false //MK: Guitar thinks Singer made it personal by changing lyrics in Mood Tattoos

=== ONBOARDING ===
#PlayerControlUntil: OnboardingComplete, JumpToPath: OPENING
In Bandocracy, YOU are in the band. So, who are you?
    -> VIEW_CHARS 
    
= VIEW_CHARS

    + Singer
        This gifted lyricist believes that anyone with musical talent should use it to help the world and not let self-doubt - or one’s own mother! - stop them.
        
        Likes - Audience connection, artist collaboration, standing up for people.
        Dislikes - Confrontation, talking about the past, inauthenticity.
        
        ++ [Be the singer!]
            ~ char_singer = true
            -> NAME 
        ++ [Check out another character.]
            -> VIEW_CHARS
        ++ [Learn why the singer started this band.]
            “Starting this new band is personal. My mom gave up her voice and wanted me to give up mine, but I can’t do that. I won’t.”
        
            +++ [Be the singer!]
                ~ char_singer = true
                -> NAME 
            +++ [Check out another character.]
                -> VIEW_CHARS
            
    + Guitarist
        An undeniable generational talent and natural star. Just ask! 
        Other people may say things like “selfish”, “inconsiderate”, or “insincere”, but what else would haters say?
        
        Likes - The spotlight, solos, recognition.
        Dislikes - Being in the background, compromise, self-righteousness.
        
        ++ [Be the guitarist!]
            ~ char_guitarist = true 
            -> NAME
        ++ [Check out another character.]
            -> VIEW_CHARS
        ++ Learn why the guitarist joined this band.
            “I bet you know me from my previous band, and now you know the comeback is ON. I’ll show everyone I DO believe in important world-changing stuff... in between face-melting guitar solos!”
            
            +++ [Be the guitarist!]
                ~ char_guitarist = true 
                -> NAME
            +++ [Check out another character.]
                -> VIEW_CHARS  
            
    + (SELECT_BASSIST)Bassist
        This cynical veteran musician believes that you can’t get too invested in changing the world, because “The People” will always find a way to mess it up.
        
        Likes - Rock-solid principles, Singer’s writing, keeping things even.
        Dislikes - Getting hopes up, posers, “the bright side”.
        
        ++ [Be the bassist!]
            ~ char_bassist = true 
            -> NAME
        ++ [Check out another character.]
            -> VIEW_CHARS
        ++ [Learn why the bassist joined this band.]
            “I used to be an optimist, but people never change, so now I hate them. But this new band might actually make a difference. Maybe. I’m wary about getting my hopes up.”
        
            +++ [Be the bassist!]
                ~ char_bassist = true 
                -> NAME
            +++ [Check out another character.]
                -> VIEW_CHARS
            
    + (SELECT_KEYS)Keyboardist
        Determined to find the bright side of anything, this young do-gooder is out to change the world with music that can be everything to everyone! 
        
        Likes - Positivity, hope, togetherness.
        Dislikes - Negativity, selfishness, conflict.
        
        ++ [Be the keyboardist!]
            ~ char_keyboardist = true 
            -> NAME
        ++ [Check out another character.]
            -> VIEW_CHARS
        ++ [Learn why the keyboardist joined this band.]
            “I’m so excited to be in my first band! I want to bring people together and make them feel so good that they go, like, into the world and do extra good things!”
            
            +++ [Be the keyboardist!]
                ~ char_keyboardist = true 
                -> NAME
            +++ [Check out another character.]
                -> VIEW_CHARS

= NAME 
Great choice! Now what's your name and pronouns?

Name _________

(In game, players will choose their character name by typing something in. For this Inky script, I've inputted default names. You can change these for your playthrough by typing another name between the quotation marks in the ink.)

    ~ name_singer = "Inez"
    ~ name_guitarist = "Strummer"
    ~ name_bassist = "Graham"
    ~ name_keyboardist = "Neptune"

Pronouns [button select]
{
- char_singer: -> PRONOUNS_SINGER
- char_guitarist: -> PRONOUNS_GUITARIST
- char_bassist: -> PRONOUNS_BASSIST
- char_keyboardist: -> PRONOUNS_KEYS
}

= PRONOUNS_SINGER

    + [She/her]
        ~ pronouns_singer = "femme"
    + [He/him]
        ~ pronouns_singer = "masc"
    + [They/them]
        ~ pronouns_singer = "enby"
    -
        -> PLAY_SINGER
    
= PLAY_SINGER
{name_singer}, eh? 
{
- pronouns_singer == "femme":
    She likes that name.
- pronouns_singer == "masc":
    He likes that name.
- else:
    They like that name.
}
Now you're ready to play!
    + PLAY
        -> OPENING 
    
= PRONOUNS_GUITARIST

    + [She/her]
        ~ pronouns_guitarist = "femme"
    + [He/him]
        ~ pronouns_guitarist = "masc"
    + [They/them]
        ~ pronouns_guitarist = "enby"
    -
    -> PLAY_GUITARIST
    
= PLAY_GUITARIST
{name_guitarist}, eh?
{
- pronouns_guitarist == "femme":
    She likes that name.
- pronouns_guitarist == "masc":
    He likes that name.
- else:
    They like that name.
}
Now you're ready to play!
    + PLAY
        -> OPENING

= PRONOUNS_BASSIST

    + [She/her]
        ~ pronouns_bassist = "femme"
    + [He/him]
        ~ pronouns_bassist = "masc"
    + [They/them]
        ~ pronouns_bassist = "enby"
    -
        -> PLAY_BASSIST

= PLAY_BASSIST
{name_bassist}, eh?
{
- pronouns_bassist == "femme":
    She likes that name.
- pronouns_bassist == "masc":
    He likes that name.
- else:
    They like that name.
}
Now you're ready to play!
    + PLAY
        -> OPENING
        
= PRONOUNS_KEYS

    + [She/her]
        ~ pronouns_keyboardist = "femme"
    + [He/him]
        ~ pronouns_keyboardist = "masc"
    + [They/them]
        ~ pronouns_keyboardist = "enby"
    -
    -> PLAY_KEYS
    
= PLAY_KEYS
{name_keyboardist}, eh?
{
- pronouns_keyboardist == "femme":
    She likes that name.
- pronouns_keyboardist == "masc":
    He likes that name.
- else:
    They like that name.
}
Now you're ready to play!
    + PLAY
        -> OPENING