BloomDigital
/
Bandocracy-ink
6
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity
Bandocracy-ink/Level 0/PRACTICE_WHALESONG.ink

396 lines
13 KiB
Plaintext
Raw Blame History

=== PRACTICE_WHALESONG ===
#Environment: PracticeSpace
#AddChar: Vez, Pose: instrument_holding
#AddChar: Skyler, Pose: instrument_holding
#AddChar: Micah, Pose: instrument_holding
#AddChar: Fern, Pose: instrument_holding
#AddChar: Akai, Pose: instrument_holding
VEZ: Okay, we're booked for the <i>Blow Your Own Hole Festival</i> at Erosion.
FERN: Erosion? Is that the cave club? I'd love to ROCK a cave! (laughs)
MICAH: I hate to endorse any pun, but yeah. The acoustics are perfect.
SKYLER: And loud! Shows at Erosion can been heard across the whole city.
FERN: Yes! I heard a whale choir practicing the other night. So beautiful!
FERN: I only wish I knew what they were singing.
SKYLER: Vez can be your translator.
FERN: VEZ, YOU SPEAK WHALEISH?!!!
VEZ: A bit. I took lessons in school, but my intonation was always a little too pitched.
MICAH: Every human's intonation is too pitched; we're not whales. It's just cool you understand the language.
FERN: SO COOL!
MICAH: Whales are smart. We should all listen to what they have to say.
SKYLER: No one disagrees with that. So our song supporting whale voices will be a sure hit!
Vez bristles...
+ (SLIDE)... but says nothing and lets Skyler's comment slide.
+ ... and decides to put Skyler in her place.
VEZ: Nothing's a sure thing, Skyler.
SKYLER: You're the band's black cloud now?
VEZ: I'm not being negative. Just a friendly reminder that you can't phone this in.
VEZ: Every song matters, even if the cause has broad support.
SKYLER: I NEVER phone it in! I'm 100% ON STAGE all the time!
VEZ: I didn't mean your stage presence, I meant writing the song.
-
#PlaySFX: Akai_attention
AKAI: SONGWRITING! LET'S DO IT!
AKAI: (sighs) What I mean is...
AKAI: I've already created two complete percussion tracks. You humans will need more time for your parts, of course.
-> CREATE_SONG
= CREATE_SONG
#UI: practice/band_playing
#PlayMusic:
//not sure how we'll start playing the music stems in this scene. Individually play default stems? Or a group default noodle? i.e. The song stems wouldn't play until players have clicked on a character and selected a stem. It'll just be the default noodle until then.
//Click on a character or click the FINISH button.
+ [DRUMS]
-> STEMS_DRUMS
+ [GUITARIST]
-> STEMS_GUITAR
+ [SINGER]
-> STEMS_VOCALS
+ [KEYS]
-> STEMS_KEYS
+ [BASSIST]
-> STEMS_BASS
+ {STEMS_DRUMS && STEMS_GUITAR && STEMS_VOCALS && STEMS_KEYS && STEMS_BASS}[FINISH]
//Once players have had a chance to select the music part for each character, this button appears.
-> SONG_JAM
= STEMS_DRUMS
#UI: practice/drums_playing
+ [PLAY STEM A]
~ drums_whalesong = "Human"
#PlayMusic: drums_whalesong_human
AKAI: {&It's a "shore party" because humans run the world.|Humans would like this beat best.}
-> STEMS_DRUMS
+ [PLAY STEM B]
~ drums_whalesong = "Whaleish"
#PlayMusic: drums_whalesong_whaleish
AKAI: {&If whales had a say, I think they'd like these drums best.|Sounds like whales shakin' things up!}
-> STEMS_DRUMS
+ [PREVIOUS CHARACTER]
-> STEMS_BASS
+ [NEXT CHARACTER]
-> STEMS_GUITAR
+ [EXIT]
-> CREATE_SONG
= STEMS_GUITAR
#UI: practice/guitar_playing
+ [PLAY STEM A] #Mood+
~ guitar_whalesong = "Human"
#PlayMusic: guitar_whalesong_human
SKYLER: {&Every song needs a guitar solo!|Will Vez think this solo is too much?|My guitar wants to wail for the whales!}
-> STEMS_GUITAR
+ [PLAY STEM B] #Mood=
~ guitar_whalesong = "Whaleish"
#PlayMusic: guitar_whalesong_whaleish
SKYLER: {&This riff isn't as exciting as the solo.|Whaley riff over solo will prove to Vez I've changed.|A whaley riff says I care about the message more than myself.}
-> STEMS_GUITAR
+ [PREVIOUS CHARACTER]
-> STEMS_DRUMS
+ [NEXT CHARACTER]
-> STEMS_VOCALS
+ [EXIT]
-> CREATE_SONG
= STEMS_VOCALS
#UI: practice/vocals_playing
+ [PLAY STEM A]
~ vocals_whalesong = "Human"
#PlayMusic: vocals_whalesong_human
VEZ: {Hmm... what rhymes with ecolocation?|Whales understand human language, so these lyrics work for everybody.|The message is what's important no matter what language it's in.|"Say it don't spray it" - seriously!|Stick to lyrics everyone understands.}
-> STEMS_VOCALS
+ [PLAY STEM B]
~ vocals_whalesong = "Whaleish"
#PlayMusic: vocals_whalesong_whaleish
VEZ: {Maybe I should sing in Whaleish.|The whales will love this, IF I can sing it right.|I haven't spoken Whaleish in years.|Ugh, my Whaleish probably sounds like Seal by now.|Did I get that intonation right?}
-> STEMS_VOCALS
+ [PREVIOUS CHARACTER]
-> STEMS_GUITAR
+ [NEXT CHARACTER]
-> STEMS_KEYS
+ [EXIT]
-> CREATE_SONG
= STEMS_KEYS
#UI: practice/keys_playing
+ [PLAY STEM A]
~ keys_whalesong = "Human"
#PlayMusic: keys_whalesong_human
FERN: {&Will our cetacean siblings like these simple chords?|This can be a backup if the band thinks synthesized whale sounds are too much.}
-> STEMS_KEYS
+ [PLAY STEM B]
~ keys_whalesong = "Whaleish"
#PlayMusic: keys_whalesong_whaleish
FERN: {&Synthesized whale sounds are so cool!|No such thing as too much whale!|THIS will blow them out of the water! In the best way.}
-> STEMS_KEYS
+ [PREVIOUS CHARACTER]
-> STEMS_VOCALS
+ [NEXT CHARACTER]
-> STEMS_BASS
+ [EXIT]
-> CREATE_SONG
= STEMS_BASS
#UI: practice/bass_playing
+ [PLAY STEM A]
~ bass_whalesong = "Human"
#PlayMusic: bass_whalesong_human
BASSIST: {&Everyone likes a classic bassline.|Is this deep enough to penetrate the ocean?|This bassline might not be salty enough for the whales.}
-> STEMS_BASS
+ [PLAY STEM B]
~ bass_whalesong = "Whaleish"
#PlayMusic: bass_whalesong_whaleish
BASSIST: {&Smooth. Like a whale. I think whales are smooth.|Might as well dive deep.|This bassline evokes whale power.}
-> STEMS_BASS
+ [PREVIOUS CHARACTER]
-> STEMS_KEYS
+ [NEXT CHARACTER]
-> STEMS_DRUMS
+ [EXIT]
-> CREATE_SONG
= SONG_JAM
#PlayMusic: L0_stem_selections
//Band plays a short segment of the song! How else will they discuss it? Not the whole song (I knew Mir wants that to be a fun reveal in the PERFORMANCE setion), but at least a section where the Vocals can be in human and/or Whaleish.
#Environment: PracticeSpace
#AddChar: Vez, Pose: instrument_playing
#AddChar: Skyler, Pose: instrument_playing
#AddChar: Micah, Pose: instrument_playing
#AddChar: Fern, Pose: instrument_playing
#AddChar: Akai, Pose: instrument_playing
#PlayerControlUntil: BandJamDone, JumpToPath: PRACTICE_WHALESONG.DISCUSS_STANCE
+ [Once the short band jam is over...]
-> DISCUSS_STANCE
= DISCUSS_STANCE
#AddChar: Vez, Pose: instrument_holding
#AddChar: Skyler, Pose: instrument_holding
#AddChar: Micah, Pose: instrument_holding
#AddChar: Fern, Pose: instrument_holding
#AddChar: Akai, Pose: instrument_holding
{ vocals_whalesong == "Whaleish":
FERN: Vez! Your Whaleish sounds AMAZING!!!
VEZ: Thanks. Though the whales might roast my pronunciation.
- else:
MICAH: Not bad, everyone.
SKYLER: {SLIDE:Like I said, surefire hit!|Yeah. Nobody phoned it in.}
FERN: It's good, but... Vez? Didn't I hear you singing some Whaleish lyrics?
VEZ: Yeah, I was playing around, but I don't think my pronunciation was right.
}
+ MICAH: The whales will appreciate that you tried.
SKYLER: (laughs) And everyone else will just think you're possessed!
Everyone glares at Skyler.
SKYLER: What? Nobody jokes about being possessed by a whale ghost anymore?
MICAH: That was never a thing.
FERN: I know you're being mean, Skyler, but you've actually given Vez a compliment!
FERN: Vez's Whaleish is so good it sounds exactly like a whale!
+ FERN: Maybe we can invite a whale to be a guest vocalist.
VEZ: Oh really? You think we should have a token whale in our band?
Awkward moment with Fern's idol! As per Mir's suggestion.
-
//revise everything below too...
SKYLER: But most people at the show won't understand Whaleish.
AKAI: MAKE THEM LEARN!
MICAH: Truth. It's way past time humans stop forcing others to assimilate as a condition of inclusion.
VEZ: I agree with you, but this song's message is more for humans than whales.
SKYLER: Yeah. And Whaleish might confuse people.
MICAH: Or give them an excuse to not understand the message.
VEZ: I only put <i>some</i> of the lyrics in Whaleish. People can still get the message.
FERN: Sing it in Whaleish! It'll make a big SPLASH! Haha!
MICAH: Easy on the puns, kid. I almost laughed.
VEZ: So, are we changing the song? Or going with what we've got?
-> SONG_DONE_L0
=== SONG_DONE_L0 ===
#UI: practice/song_created
//The Bandocracy UX Storyboard shows the characters' moods towards each song stance, but because the song isn't set in stone yet, I decided not to put these in as variables. Plus, the variables are cumulative over the course of the game. Instead, I propose using Hashtags to display how the characters feel for each version. UI also had a little dialogue bubble beside each, so I put that in too.
{vocals_whalesong == "Whaleish":
AKAI: KEEP IT! #Mood+
SKYLER: Change it. #Mood-
VEZ: I don't know... #Mood=
FERN: Love it! #Mood+
MICAH: Doesn't matter. #Mood=
- else:
AKAI: TRASH IT! #Mood-
SKYLER: Keep it. #Mood+
VEZ: I don't know... #Mood=
FERN: Boo. #Mood-
MICAH: Doesn't matter. #Mood=
}
+ {not EDIT_WHALESONG}[EDIT SONG]
-> EDIT_WHALESONG
+ [HEAD TO SHOW]
VEZ: Alright, we've got our first song!
-> PERFORM_WHALESONG
=== EDIT_WHALESONG ===
//NOTE: I thought of pointing this back to CREATE_SONG, but this section needs new thoughts about the stems now that the band has discussed how they feel about the song. Hence this NEW knot! Also makes it easy to check if players chose to edit a song or not.
#UI: practice/band_playing
#PlayMusic:
//Click on a character or click the FINISH button.
+ [GUITARIST]
-> STEMS_GUITAR
+ [SINGER]
-> STEMS_VOCALS
+ [KEYS]
-> STEMS_KEYS
+ [BASSIST]
-> STEMS_BASS
+ [FINISH]
-> SONG_DONE_L0
= STEMS_DRUMS
#UI: practice/drums_playing
+ [PLAY STEM A]
~ drums_whalesong = "Human"
#PlayMusic: drums_whalesong_human
AKAI: It'll be a "shore party" no matter what.
-> STEMS_DRUMS
+ [PLAY STEM B] #Mood+
~ drums_whalesong = "Whaleish"
#PlayMusic: drums_whalesong_whaleish
AKAI: Underwater percussion for the whales!
-> STEMS_DRUMS
+ [PREVIOUS CHARACTER]
-> STEMS_BASS
+ [NEXT CHARACTER]
-> STEMS_GUITAR
+ [EXIT]
-> EDIT_WHALESONG
= STEMS_GUITAR
#UI: practice/guitar_playing
+ [PLAY STEM A] #Mood+
~ guitar_whalesong = "Human"
SKYLER: Rocking guitar solo for ME!
-> STEMS_GUITAR
+ [PLAY STEM B]
~ guitar_whalesong = "Whaleish"
SKYLER: Whaley guitar for the CAUSE!
-> STEMS_GUITAR
+ [PREVIOUS CHARACTER]
-> STEMS_BASS
+ [NEXT CHARACTER]
-> STEMS_VOCALS
+ [EXIT]
-> EDIT_WHALESONG
= STEMS_VOCALS
#UI: practice/vocals_playing
+ [PLAY STEM A]
~ vocals_whalesong = "Human"
VEZ: A clear message for all!
-> STEMS_VOCALS
+ [PLAY STEM B]
~ vocals_whalesong = "Whaleish"
VEZ: Acculturation not assimilation!
-> STEMS_VOCALS
+ [PREVIOUS CHARACTER]
-> STEMS_GUITAR
+ [NEXT CHARACTER]
-> STEMS_KEYS
+ [EXIT]
-> EDIT_WHALESONG
= STEMS_KEYS
#UI: practice/keys_playing
+ [PLAY STEM A] #Mood-
~ keys_whalesong = "Human"
FERN: This sounds good no matter what lyrics Vez chooses.
-> STEMS_KEYS
+ [PLAY STEM B] #Mood+
~ keys_whalesong = "Whaleish"
FERN: Whaley harmonics to go with Whaleish lyrics.
-> STEMS_KEYS
+ [PREVIOUS CHARACTER]
-> STEMS_VOCALS
+ [NEXT CHARACTER]
-> STEMS_BASS
+ [EXIT]
-> EDIT_WHALESONG
= STEMS_BASS
#UI: practice/bass_playing
+ [PLAY STEM A]
~ bass_whalesong = "Human"
MICAH: Keep it simple. For the people.
-> STEMS_BASS
+ [PLAY STEM B]
~ bass_whalesong = "Whaleish"
MICAH: Make it deep. For the whales.
-> STEMS_BASS
+ [PREVIOUS CHARACTER]
-> STEMS_KEYS
+ [NEXT CHARACTER]
-> STEMS_GUITAR
+ [EXIT]
-> EDIT_WHALESONG
Reference in New Issue View Git Blame Copy Permalink