Bandocracy-ink/Level1/PRACTICE_MOODTATTOOS.ink

-> PRACTICE_MOODTATTOOS

=== PRACTICE_MOODTATTOOS ===
KEYBOARDIST: We should get mood tattoos for the show! Smiley faces! Or a happy sun?

GUITARIST: Those are very "rock and roll" options. //NOTE for Art: We'll need a sarcastic expression for Guitarist and Bassist. Keys and Singer likely don't need sarcastic.
GUITARIST: But you're assuming we're all pro-tattoo. 

KEYBOARDIST: We should be! They totally promote deeper connections and reduce conflict. Science says so.

SINGER: Yes, it seems like people with Mood Tattoos are less prone to conflict...
SINGER: ... but there's more to communication than moods. Those tattoos can't replace words. 

BASSIST: But, people can lie with words. They CAN'T lie if everyone can see how full of shit they are. That's good. 
    
GUITARIST: Don't people have the right to hide something if they want to? 
GUITARIST: What matters is what we put out there for the crowd, not what's inside.

KEYBOARDIST: But you could also show people that you aren't hiding _anything_. 

GUITARIST: I... hadn't thought of it that way.

SINGER: What about the people who created Mood Tattoos? Why do they _want_ people to have them? What are they hiding?

KEYBOARDIST: We should at least be open with each other. Are we for, or against, Mood Tattoos?

DRUMMER: I know humans prefer to argue, but you should vote. //ha!

#SPLITFLOW

{
- char_singer:
    -> SINGER_THOUGHTS
- char_guitarist:
    -> GUITARIST_THOUGHTS
- char_bassist:
    -> BASSIST_THOUGHTS
- char_keyboardist:
    -> KEYBOARDIST_THOUGHTS
}

= SINGER_THOUGHTS
SINGER: Mood tatoos were created by The Unvoiced and no one even knows.
SINGER: But if I bring that up... I'll have to tell {name_bassist} and {name_keyboardist} about my mom.  
-> VOTE_TIME

= GUITARIST_THOUGHTS
GUITARIST: I know I've changed. So why do I think I'm lying to myself? Whatever... that's for my therapist.
GUITARIST: If we promote those tattoos, I'll have to get one. And I'm not going to risk flashing that doubt to all my fans. 
GUITARIST: If I am lying to myself, I don't want to know. Or tell. 
    -> VOTE_TIME

= BASSIST_THOUGHTS
BASSIST: {name_singer} really doesn't like mood tattoos. But, warning people away from them seems paranoid.
BASSIST: Unless there's a conspiracy {pronouns_singer == "enby": they want|{pronouns_singer == "masc": he|she} wants} to blow up. That sounds fun. But, so does watching liars get called out. //HJ: I was going to suggest using the name_singer variable again because that is simplest, but then I figured out how to check all 3 pronouns IN LINE without making a conditional block. So, thanks for prompting me to figure that out!
    -> VOTE_TIME
    
= KEYBOARDIST_THOUGHTS
KEYBOARDIST: I can't believe anyone wouldn't want to wear their mood on the outside!
KEYBOARDIST: I wish I was old enough to get a tattoo. I wish I could lie about being old enough! But I don't like lying...
    -> VOTE_TIME

= VOTE_TIME
#REJOIN
#PlayerControlUntil: VoteComplete, JumpToPath: PRACTICE_MOODTATTOOS.VOTE_RESULTS
    + [VOTE ON IT!]
        -> VOTE

= VOTE 
{
- char_singer:
    -> VOTE_SINGER
- char_guitarist:
    -> VOTE_GUITARIST
- char_bassist:
    -> VOTE_BASSIST
- char_keyboardist:
    -> VOTE_KEYBOARDIST
}

= VOTE_SINGER

    + [Get a Mood Tattoo!] 
        ~ vote_songstance_protattoo++
    + [Don't Get a Mood Tattoo!]
        ~ vote_songstance_antitattoo++
    -

    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    -> VOTE_RESULTS
    
= VOTE_GUITARIST

    + [Get a Mood Tattoo!]
        ~ vote_songstance_protattoo++
    + [Don't Get a Mood Tattoo!]
         ~ vote_songstance_antitattoo++
    -

    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    -> VOTE_RESULTS
    
= VOTE_BASSIST

    + [Get a Mood Tattoo!]
        ~ vote_songstance_protattoo++
    + [Don't Get a Mood Tattoo!]
         ~ vote_songstance_antitattoo++
    -

    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    -> VOTE_RESULTS
    
= VOTE_KEYBOARDIST

    + [Get a Mood Tattoo!]
        ~ vote_songstance_protattoo++
    + [Don't Get a Mood Tattoo!]
        ~ vote_songstance_antitattoo++
    -

    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    
    {shuffle:
    - 
        ~ vote_songstance_protattoo++
    - 
        ~ vote_songstance_antitattoo++
    }
    -> VOTE_RESULTS
    
= VOTE_RESULTS
{
- vote_songstance_protattoo == 4:
    ~ band_unity +=2  
    -> STANCE_COMEGET
- vote_songstance_protattoo == 3:
    ~ band_unity +=1 
    -> STANCE_COMEGET
- vote_songstance_antitattoo == 4:
    ~ band_unity +=2 
    -> STANCE_DONTGET
- vote_songstance_antitattoo == 3:
    ~ band_unity +=1 
    -> STANCE_DONTGET
- else:
    {not TIE_RULES: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE } //If players have not heard the TIE RULES, go there in the event of a tie vote. Otherwise, players already know the rule is Drummer's Choice.
}

= TIE 
~ vote_songstance_protattoo = 0
~ vote_songstance_antitattoo = 0
//Reset votes ^ and send players back to VOTE...

#PlayerControlUntil: VoteComplete, JumpToPath: PRACTICE_moodtattoos.VOTE_RESULTS
    + [Vote again!]
        -> VOTE
        
= DRUMMER_CHOICE
~ band_unity-- //band couldn't agree, so band unity drops. 
DRUMMER: You couldn't agree, so I have to break the tie. 
DRUMMER: This would be awkward if you had your tattoos already... //ha!

{shuffle: 
- 
    -> STANCE_COMEGET
- 
    -> STANCE_DONTGET
}
        
= STANCE_COMEGET
DRUMMER: You're telling people to Come Get a Mood Tattoo!
~ band_stance_L1 = "People"
~ song_stance_L1 = "Pro-Tattoo"
/*NOTE: I created 2 variables in order to... 
    1) compare band_stance to band_vision to see if they're equal or not, and thus these variables need the same values, "Rebels" or "People".
    2) compare song_stance_L1 to vocals_whalesong, the same way as above, using the values "Pro-Tattoo" or "Anti-Tattoo".
*/

#SPLITFLOW
{
- char_singer:  
    -> SINGER_FEELS_COMEGET
        
- char_guitarist: 
    -> GUITARIST_FEELS_COMEGET
        
- char_bassist:
    -> BASSIST_FEELS_COMEGET
        
- char_keyboardist:
    -> KEYS_FEELS_COMEGET
}

= SINGER_FEELS_COMEGET

    + [I can work with that.]
        SINGER: I don't like it... but I don't have to say The Unvoiced are lovable. #THOUGHT
    + [I'll make this my own.] //MK: I'm thinking this can be a choice reaction, but it's still not really going to work out later... //HJ: For sure, but the wording of this makes it sound as if Singer is going to break ranks a bit, like Singer isn't a team player. But I think what Singer really means is, "I don't like it, but I'll work with it." Shorter version: "I can work with that." As opposed to the first choice which is a blunt refusal. //MK: Tried this, but "work with it" and "make it my own" are kinda the same. 
        SINGER: I'll make mood tattoos sound like a communication tool. Not a replacement for spoken words. #THOUGHT
    -
    
{DRUMMER_CHOICE: 
    SINGER: I should have programmed Akai to "randomly" vote my way... #THOUGHT
    //HJ: Hmm... it's not the vote but Akai's random shuffle program that Singer should have rigged. Something about wishing they'd preprogammed Akai to choose DON'T Get a Tattoo. //MK: rig the vote, and you don't get to Akai at all, though.
}
    -> MOODTATTOOS_STEMS

= GUITARIST_FEELS_COMEGET
//MK: Guitar didn't want tattoos, but waffled a bit

{DRUMMER_CHOICE: 
    GUITARIST: Does Akai secretly want a mood...paint job? #THOUGHT 
}
    + [I hate this.]
        GUITARIST: This comeback could be over before it starts if I get one of these things. #THOUGHT 
    + [I don't like this, but I'll rise above it.]
        GUITARIST: I'll make mood tattoos sound badass. I can always refuse to get one. #THOUGHT 
    -

    -> MOODTATTOOS_STEMS
    
= BASSIST_FEELS_COMEGET

    + [This will be so satisfying.]
        BASSIST: I hope every bullshit artist gets cornered into getting a mood tattoo. #THOUGHT 
        BASSIST: If only my dickhead first manager had had one. #THOUGHT
    + [Whatever.]
        BASSIST: The drama will be fun to watch... #THOUGHT 
        BASSIST: But I wonder if {name_singer} could have pulled off a paranoia anthem. #THOUGHT 
    -
    
{DRUMMER_CHOICE:
    BASSIST: Akai probably wants robots to be able to recognize human lies. Smart. #THOUGHT 
}
    -> MOODTATTOOS_STEMS
    
= KEYS_FEELS_COMEGET

    + [Yes! YES!]
        KEYBOARDIST: If you're happy and you know it... then, we will also know it! #THOUGHT 
        KEYBOARDIST: If you're happy and you know it, get a tat! #THOUGHT 
    + [I wish everyone was excited.]
        KEYBOARDIST: Their mood tattoos are probably going to be, like, beige. All the time. #THOUGHT 
    - //Hahahahahaha! Love the voice you've created for Keys!
    
{DRUMMER_CHOICE:
    KEYBOARDIST: I'm glad Akai can choose, so we don't start fighting. #THOUGHT 
}
    -> MOODTATTOOS_STEMS
    
= STANCE_DONTGET
DRUMMER: Tell people NOT to get a mood tattoo!
~ band_stance_L1 = "People"
~ song_stance_L1 = "Anti-Tattoo"

#SPLITFLOW
{
- char_singer:
    -> SINGER_FEELS_DONTGET

- char_guitarist:
    -> GUITARIST_FEELS_DONTGET
        
- char_bassist:
    -> BASSIST_FEELS_DONTGET
        
- char_keyboardist:
    -> KEYS_FEELS_DONTGET
}

= SINGER_FEELS_DONTGET

    + [That's a relief.]
        SINGER: I didn't want to sing something I don't feel. #THOUGHT 
    + [Time to hit back at The Unvoiced!] //HJ: As a choice, this line is a bit too vague to mean anything to the player. Try something more specific, like, "Time to hit back at The Unvoiced!" so that players know what this choice means and why they'd choose it. 
        SINGER: This isn't how I thought I'd get revenge on The Unvoiced, but I'll take it. #THOUGHT 
    + [I'm worried this is too negative.]
        SINGER: I hope I can still make "don't do this" sound fun. #THOUGHT 
    -
    
    -> MOODTATTOOS_STEMS

= GUITARIST_FEELS_DONTGET
//MK: again - I think Guitarist is waffling.

    + [Good. No broadcasting these feelings.] 
        GUITARIST: Okay, maybe I am hiding. And maybe I don't care. #THOUGHT 
    + [What if I really have changed?]
        GUITARIST: A mood tattoo would shut everyone up. #THOUGHT 
    + [I'm safe. But, this won't be a hit.] 
        GUITARIST: "Don't Do That" has never cracked any top ten. #THOUGHT 
    - 
    
    -> MOODTATTOOS_STEMS
    
= BASSIST_FEELS_DONTGET

    + [This song is pointless.]  
        BASSIST: Why make a song telling people to do nothing? #THOUGHT 
    + [I'll trust {name_singer}'s approach.]
        BASSIST: {name_singer} is smart. They must have something to expose. Let's see. #THOUGHT 
    -
    
{DRUMMER_CHOICE:
    BASSIST: Akai must think human problems are stupid. Well, they are. #THOUGHT 
}
    -> MOODTATTOOS_STEMS

= KEYS_FEELS_DONTGET

    + [This is the WORST.]
        KEYBOARDIST: I didn't join this band to preach negativity. I fell icky. Like I have a runny nose. #THOUGHT 
    + [I'll get a tattoo anyway!]
        KEYBOARDIST: Then, they'll know how unhappy I am! Which is good because I don't want to say so. #THOUGHT 
    - 
    
{DRUMMER_CHOICE:
    KEYBOARDIST: Aw. Akai would love a cool mood indicator light. #THOUGHT  
}
    -> MOODTATTOOS_STEMS
    
=== MOODTATTOOS_STEMS ===  
#REJOIN
DRUMMER: While you all were reacting to the vote, I created two simple beats for a simple message. //HJ: I added the line from WhaleSong to the beginning of this line for a smoother transition out of the players' private screens. 
DRUMMER: We can get people dancing... 
#PlayMusic: drums_moodtattoo_pro

DRUMMER: Or, we can go all minimalist...
#PlayMusic: drums_moodtattoo_anti

{song_stance_L1 == "Pro-Tattoo": 
//MK: went with what they're feeling would be based on how the stem actually sounds. Included Singer here because they don't like this stance. Tried leaving Guitar on the outside this time, since they're only worried about themselves. //HJ: Good call!
    KEYBOARDIST: I love the dancey one! 
    SINGER: It's fun, for sure. But should it sound like a party? That's a bit commercial. 
    BASSIST: Yeah, but we don't want to sound like we're inviting people into a deadly trap. At least, I assume we don't.
    
- else:
    KEYBOARDIST: That minimalist beat is a bit ominious. I'm already worried.
    SINGER: Well, we want to steer people away from mood tattoos. But, we could make a fun "don't do it" song. 
    BASSIST: If we're going dark, we should go dark. A warning is a warning.
    BASSIST: ... Let me know if I should say any other words twice.
}

GUITAR: They're both good options, right? Let's just vote. 

DRUMMER: Okay. It sounds like you're done talking about it. 

#PlayerControlUntil: VoteComplete, JumpToPath: MOODTATTOOS_STEMS.VOTE_RESULTS
    + [VOTE ON THE BEAT!]
        -> VOTE_DRUMS

= VOTE_DRUMS
{
- char_singer:
    -> VOTE_SINGER
- char_guitarist:
    -> VOTE_GUITARIST
- char_bassist:
    -> VOTE_BASSIST
- char_keyboardist:
    -> VOTE_KEYBOARDIST
}

= VOTE_SINGER

    + [Minimalist.]
        ~ vote_moodtattoo_drums_anti++
    + [Dance Track.]
        ~ vote_moodtattoo_drums_pro++
    -

    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    -> VOTE_RESULTS
    
= VOTE_GUITARIST

    + [Minimalist.]
        ~ vote_moodtattoo_drums_anti++
    + [Dance Track.]
         ~ vote_moodtattoo_drums_pro++
    -

    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    -> VOTE_RESULTS
    
= VOTE_BASSIST

    + [Minimalist.]
        ~ vote_moodtattoo_drums_anti++
    + [Dance Track.]
        ~ vote_moodtattoo_drums_pro++
    -

    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    -> VOTE_RESULTS
    
= VOTE_KEYBOARDIST

    + [Minimalist.]
        ~ vote_moodtattoo_drums_anti++
    + [Dance Track.]
        ~ vote_moodtattoo_drums_pro++
    -

    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    
    {shuffle:
    - 
        ~ vote_moodtattoo_drums_anti++
    - 
        ~ vote_moodtattoo_drums_pro++
    }
    -> VOTE_RESULTS
    
= VOTE_RESULTS
DRUMMER: Votes are in. 
{
- vote_moodtattoo_drums_anti >= 3:
    ~ drums_moodtattoo = "Anti-Tattoo"
    -> DRUMS_ANTI
- vote_moodtattoo_drums_pro >= 3:
    ~ drums_moodtattoo = "Pro-Tattoo"
    -> DRUMS_PRO
- else:
    {not TIE_RULES: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE } //If players have not heard the TIE RULES, go there in the event of a tie vote. Otherwise, players already know the rule is Drummer's Choice.
}

= TIE 
~ vote_moodtattoo_drums_anti = 0
~ vote_moodtattoo_drums_pro = 0
//Reset votes ^ and send players back to VOTE...

#PlayerControlUntil: VoteComplete, JumpToPath: MOODTATTOOS_STEMS.VOTE_RESULTS
    + [Vote again!]
        -> VOTE_DRUMS
        
= DRUMMER_CHOICE
DRUMMER: The vote is a tie. Ties are made to be broken.

{shuffle: 
- 
    ~ drums_moodtattoo = "Anti-Tattoo"
    -> DRUMS_ANTI
- 
    ~ drums_moodtattoo = "Pro-Tattoo"
    -> DRUMS_PRO
}

= DRUMS_ANTI
DRUMMER: Drum level minimum. Beep.
    -> CHOOSE_MUSIC_STEMS
    
= DRUMS_PRO
DRUMMER: LET'S DANCE!
    -> CHOOSE_MUSIC_STEMS

= CHOOSE_MUSIC_STEMS
DRUMMER: Well. I've done my part...
DRUMMER: ...entering Sleep Mode. //ha!

SINGER: Rude. I guess it's our turn, now. 
#SPLITFLOW

{
- char_singer:  
    -> VOCAL_STEMS
        
- char_guitarist: 
    -> GUITAR_STEMS
        
- char_bassist:
    -> BASS_STEMS
        
- char_keyboardist:
    -> KEYS_STEMS
}

/* BIG NOTE!!!

HJ: I renamed all the stem choices to make it clear that they are simple visual buttons, not text choices. Also, I've learned that in the UX code, Keana names the buttons whatever we put between these square brackets, so short and sweet and consistent across songs & levels is best!

HJ: Now that you know the buttons won't have bespoke text lines on them, a few of the character thoughts need to be revised to respond to the SOUND of the music stem, rather than the stem's description (which players can't see). So, Keyboardist's responses are perfect: "This is a sound for a brighter world!" or "This one is sneaky." <- Okay, maybe I'd revise that to "This sounds sneaky." But Singer's first thought, "I can't help the Unvoiced with this." doesn't really make sense as a first response. Nor does Guitarist's "Maybe something downbeat?" <- That one's an easy fix; you could simply add, "Too wistful." to the beginning of that line. So, go through and revise the character's reactions to their musical parts. And remember, we can't predict what order players will press the buttons in, or how often. In other words, there's no guarantee they'll press A first, so B shouldn't call out how B sounds in comparison to A, or vice versa. /MK: got it. I was also trying to make some of the thoughts sound like they were just coming to the characters. If they sound like they're listening to something they've already done, the way the player is, as opposed to composing it based on how they want it to sound, it doesn't make sense. Hopefully, these changes work.

*/

= VOCAL_STEMS //MK: The lyrics make no mention of the Unvoiced, and lean on the corporate conspiracy angle. Overall, the corp angle, if real, should affect Bass and Keys, too. I can do that. //HJ: Yeah, this song was written before we even knew the cult would be involved! But I don't think Singer would call out the cult in the lyrics anyway, so this works. 

    + [PLAY-A] //Encourage Mood Tattoos
        #PlayMusic: vocals_moodtattoo_pro
        //HJ: Idea! Singer's thoughts could be a little like they're humming the lyrics to themselves and reacting directly to them. For example, SINGER: "We’re taking care of you..." Ugh. Are we, though? //MK: Yeah. We should do this for all of the lyrics.
        SINGER: {&"...we're taking care of you"... but, who's we?|"Emotion should be certain..." So...maybe talk about it, too...|"Everyone will be in sync..." but hopefully not silent.|It sounds nice, but I don't know about this.} 
        -> VOCAL_STEMS
    + [PLAY-B] //Hate On Mood Tattoos 
        #PlayMusic: vocals_moodtattoo_anti
        SINGER: {&"Don't get a mood tattoo...they are watching you..." No point in being subtle.|"Don't let them inscribe it". Yeah. They decide how your feelings look.| Going after their corporation is a good idea.|"Don't drink their kool-aid?" Well, not subtle is not subtle.}
        -> VOCAL_STEMS
    + [CHOOSE-A] //Choose Come Get a Mood Tattoo.
        ~ vocals_moodtattoo = "Pro-Tattoo"
        -> MOODTATTOOS_JAM
    + [CHOOSE-B] //Choose Don't Get a Mood Tattoo.
        ~ vocals_moodtattoo = "Anti-Tattoo"
        -> MOODTATTOOS_JAM
    
= GUITAR_STEMS

    + [PLAY-A] //Play a wistful guitar.
        #PlayMusic: guitar_moodtattoo_pro
        GUITARIST: {&|People will want to hear the "community"...| This has a good "let's get together" energy.| Everything will be nice 'n easy. Wow, that sounds boring.| It's hard to make "everybody show their feelings" exciting.}
        -> GUITAR_STEMS 
    + [PLAY-B] //Play moody guitar.
        #PlayMusic: guitar_moodtattoo_anti
        GUITARIST: {&A little "WOWwowoooo' is pretty sinister.|Yeah, it needs to sound serious, not soothing.| Gotta highlight the warning vibe.|...but not be too scary. It's gotta sound cool. }
        -> GUITAR_STEMS
    + [CHOOSE-A] //Choose wistful riff.
        ~ guitar_moodtattoo = "Pro-Tattoo"
        -> MOODTATTOOS_JAM
    + [CHOOSE-B] //Choose moody riff.
        ~ guitar_moodtattoo = "Anti-Tattoo"
        -> MOODTATTOOS_JAM
    
= BASS_STEMS 

    + [PLAY-A] //Play stealthy bass.
        #PlayMusic: bass_moodtattoo_pro
        BASSIST: {&We want people to get tattoos NOW.| Something simple to support the lyrics...| Keep the energy up for the CEOs. Energy means profit!| And, surprise! Your face shows your lies! Run.}
        -> BASS_STEMS
    + [PLAY-B] //Play insistent bass.
        #PlayMusic: bass_moodtattoo_anti
        BASSIST:{&Sounds like something is chasing me.| Uh-oh. I might not get what I want...|...maybe I'm the one running. Away from something.|Yeah. This says "don't let it get you".}
        -> BASS_STEMS
    + [CHOOSE-A] //Choose stealthy bass.
        ~ bass_moodtattoo = "Pro-Tattoo"
        -> MOODTATTOOS_JAM
    + [CHOOSE-B] //Choose insistent bass.
        ~ bass_moodtattoo = "Anti-Tattoo"
        -> MOODTATTOOS_JAM

    
= KEYS_STEMS

    + [PLAY-A] //Play an aspirational tune.
        #PlayMusic: keys_moodtattoo_pro
        KEYBOARDIST: {&This is a sound for a brighter world!|I want to be part of this...|Yeah, this sounds the way a positive choice feels.|We're saying "no one will be alone".}
        -> KEYS_STEMS
    + [PLAY-B] //Play a sneaky tune.
        #PlayMusic: keys_moodtattoo_anti
        KEYBOARDIST: {&This one sounds sneaky.|This makes me wonder why mood tattoos even exist.| I'm kinda worried playing this.| This would scare people. But, do I want that?}
        -> KEYS_STEMS
    + [CHOOSE-A] //Choose aspirational tune.
        ~ keys_moodtattoo = "Pro-Tattoo"
        -> MOODTATTOOS_JAM
    + [CHOOSE-B] //Choose sneaky tune.
        ~ keys_moodtattoo = "Anti-Tattoo"
        -> MOODTATTOOS_JAM

    
=== MOODTATTOOS_JAM ===
#REJOIN
DRUMMER: ARE YOU READY TO---
DRUMMER: (sigh) Rock. And yes, you are. That's why we're here. //ha!

KEYBOARDIST: It's okay, Akai. We know you're trying to control it. //love 

DRUMMER: ... Thanks. Okay, let's jam.

#PlayMusic: {drums_moodtattoo}
#PlayMusic: {vocals_moodtattoo}
#PlayMusic: {guitar_moodtattoo}
#PlayMusic: {bass_moodtattoo}
#PlayMusic: {keys_moodtattoo}
//NOTE: I have to talk to JP about the above. I think this might trigger the music stems a split second apart, which will sound like crap. We might need a different command for this, but for now, you get the idea. 

{song_stance_L1 == vocals_moodtattoo: //Check if stance the band chose and lyrics the singer chose are the same.
    -> LYRICS_MATCH_STANCE
- else:
    -> DISSENTER_SINGER
}

= LYRICS_MATCH_STANCE
{song_stance_L1 == "Anti-Tattoo":
    -> DONT_GET_TATTOO //MK: didn't change these terms...
- else:
    -> COME_GET_TATTOO
}

= DONT_GET_TATTOO
SINGER: I hope this works. People probably haven't even thought about the tattoos recording their moods. 

KEYBOARDIST: Should we?! You really seem to hate these tattoos a lot. Why?

SINGER: ... They just... I guess I don't like the pressure to get them.

BASSIST: This is cool. I thought you'd have a conspiracy angle. Let's expose it.
    -> LOCKED_SONG 
    
= COME_GET_TATTOO
SINGER: I'm sorry. This is the best I can do. I can't sing what I don't believe, so this is what's left.

BASSIST: It's good. Feels like a hug. And some greasy bastards will be lured in and exposed. //HJ: lired??

KEYBOARDIST: I love it! And just because of the hug thing. Not the greasy bastard thing. 

GUITAR: Just so everyone knows. I do _not_ want to get one of these tattoos. That's all.

    -> LOCKED_SONG 

//NOTE: Since everyone is in agreement, we don't need to give players a choice to change or "lock in" their musical choices. We can simply move on. 

= DISSENTER_SINGER
{vocals_moodtattoo == "Anti-Tattoo":
    KEYBOARDIST: That was so scary, {name_singer}. Why would you do this?
    
    BASSIST: Yeah, I'm down to call out a corporate conspiracy, but that's not what we're doing. Right?
    
    GUITARIST: Let's hear {name_singer} out. But I'm good with it, for one. 
    
- else:
    BASSIST: Are you trying to be ironic, {name_singer}? 'Cause people might miss that. 
    
    GUITARIST: Hey! If I have to suck it up and play, why do you get to go against the band?
    
    KEYBOARDIST: Are you... making fun of people? Are you making fun of me?
   
}

SINGER: I know I went the other way. But...

    + SINGER: It won't happen again. I'm sorry. 
    + SINGER: That's they way I needed to go.
    -
    
DRUMMER: Are you locked in? Or do you want to change something?

#PlayerControlUntil: StemsLocked, JumpToPath: MOODTATTOOS_JAM.LOCKED_SONG
    + [BUTTONS POP UP - "Lock it in." or "Change it."]
        -> CHANGE_STEMS

= CHANGE_STEMS
//NOTE: This won't be in split flow anymore, and the choices below are just for singleplayer Inky playthough purposes.
{
- char_singer:  
    -> SINGER_STEM_LOCK
        
- char_guitarist: 
    -> GUITARIST_STEM_LOCK
        
- char_bassist:
    -> BASSIST_STEM_LOCK
        
- char_keyboardist:
    -> KEYS_STEM_LOCK
}

= SINGER_STEM_LOCK

    + [Keep the lyrics.]
    + [Change them!]
        ++ [Don't Get a Mood Tattoo.]
            ~ vocals_moodtattoo = "Anti-Tattoo"
        ++ [Come Get a Mood Tattoo.]
            ~ vocals_moodtattoo = "Pro-Tattoo"
        --
    -
    -> LOCKED_SONG
    
= GUITARIST_STEM_LOCK

    + [Keep it.]
    + [Change it.]
        ++ [Wistful guitar.]
            ~ guitar_moodtattoo = "Pro-Tattoo"
        ++ [Moody doom guitar.] 
            ~ guitar_moodtattoo = "Anti-Tattoo"
        --
    -
    -> LOCKED_SONG
    
= BASSIST_STEM_LOCK

    + [Keep it.]
    + [Change it.]
        ++ [Stealthy bass to lure them in.]
            ~ bass_moodtattoo = "Pro-Tattoo"
        ++ [Insistent chase bass.]
            ~ bass_moodtattoo = "Anti-Tattoo"
        --
    -
    -> LOCKED_SONG

= KEYS_STEM_LOCK 

    + [Keep it.]
    + [Change it!]
        ++ [Aspirational 'praise mood tattoos' keys!]
            ~ keys_moodtattoo = "Pro-Tattoo"
        ++ [Sneaky conspiracy keys. Watch out!]
            ~ keys_moodtattoo = "Anti-Tattoo"
        --
    -
    -> LOCKED_SONG
    
= LOCKED_SONG
SINGER: And that's a wrap on practice. We're ready for Read Only.

KEYBOARDIST: Has anyone played that place before?

BASSIST: Yeah. It's... kinda grumpy. But fun. If you're grumpy.

KEYBOARDIST: ... Oh.
    -> PERFORMANCE_MOODTATTOOS