=== POSTSHOW_WHALESONG ===
#Environment: Erosion_postshow

#AddChar: Vez, Pose: neutral
#AddChar: Skyler, Pose: neutral
#AddChar: Micah, Pose: neutral
#AddChar: Fern, Pose: neutral
#AddChar: Akai, Pose: neutral

AKAI: LET'S GET WASTED!

VEZ: I think Akai means "great first show!"

AKAI: I never said you were great. But half the crowd seemed to love it.

{L0_song == "Whale Song in Whaleish":
    ~ community_analogs = true
    ~ community_whales = true
    
    SKYLER: Half? Told you Whaleish wouldn't connect with all the fans.

    FERN: Not true! We've been invited to not one but TWO communities on Harmony!
    
    AKAI: WOOO! BUST OUT THE PREMIUM OIL!

    AKAI: For me. You all can drink champagne or whatever. 

    MICAH: Which communities? 

- else:
    ~ community_allforall = true
    
    SKYLER: Your robot eyes must need adjustment 'cause EVERYONE was grooving along, even the whales and those unplugged weirdos.
    
    VEZ: The Analogs aren't weird. 
    
    FERN: No, but even though they liked the song, they were disappointed Vez didn't sing any lyrics in Whaleish.
    FERN: AND they told the whales that Vez knows Whaleish, so then the whales were disappointed too. 
    
    MICAH: How do you know that?
    
    FERN: I read it on Harmony! <i>All For All</i> invited us to their community and they're pretty big gossips.
    
    SKYLER: What else are they saying? 
}

FERN: Go see for yourself!
#ShowHarmonyButton
//The above command was #ShowCameraControls in Cursed Café and I think we can use the same command structure here to show the Harmony button for the first time. After this, the Harmony button will always be available to the player to click or ignore, but for this first time, I think we should make players click on it. 

    + [HARMONY]
        //Players click on the "Harmony" button to see the communities they now have access to.
        -> HARMONY -> 
        //In this ink script, Harmony is its own file that acts like a "tunnel", meaning it points back to wherever scene the player came from.  
    -
 
{L0_song == "Whale Song in Whaleish":
    -> ICONOCLASTS

- else:
    -> IDEALISTS
}
   
= ICONOCLASTS

VEZ: We did it! Whales are now part of the Bandocracy.

FERN: YAY! Our first song influenced positive change!

SKYLER: How'd the whales get on Harmony so fast? Hire someone with thumbs?

AKAI: Get over yourself. Thumbs aren't necessary in a voice-controlled world.

MICAH: The whales have been on Harmony for a while, they just needed us to listen to their ideas.

FERN: And now we're listening! 

SKYLER: Not that you understand what the whales are saying. 

FERN: I will soon! I'm signing up for Whaleish lessons RIGHT NOW.
FERN: Want me to sign you up too?

    + SKYLER: Sure. Personal growth is part of my comeback.
        ~ Skyler_growth++
        
    + SKYLER: Nah. I'm not a linguist like Vez.
    -

    -> RELATIONSHIP

= IDEALISTS
//HJ: I'm running out of time so I just paraphrased this section...
Vez is annoyed that people are placing bets on whether they and Skyler will get back together.

{Skyler_growth >= 0:
    Like Fern, who bet that they'd get back together. 
    What? Fern just really wants them to give love a second chance! They were such a hot couple!
- else:
    Fern bet that Vez and Skyler wouldn't get back together.
    Vez says that was a smart bet.
    Onmniscent narrator comments that Skyler looks disappointed but also determined.
}

Fern directs the band back to the bright side - <i>All For All</i> REALLY LOVED Whale Song.

Micah points out that their song didn't convince the bureaucritics to change anything, though. 
The whales still aren't part of the Bandocracy.

Fern - not yet! They still could be. Sometime... soonish?

    -> RELATIONSHIP

= RELATIONSHIP
#PlaySFX: Akai_excited
AKAI: THERE IS NO ENCORE! 
AKAI: (sigh) Time to go. I'm not programmed to pack up the gear, by the way.

#RemChar: Akai

Once the others finish packing up...

MICAH: You need a ride, kid?

FERN: Depends what you're driving!

MICAH: Cargo trike. Bucket's got a padded seat and everything. 

FERN: YES! Can I ring the bell?!

MICAH: No.

FERN: Fair. I probably can't reach it from the bucket seat anyway.

MICAH: No, you can't. Let's go.

FERN: Bye, Vez! Bye, Skyler! 

#RemChar: Micah
#RemChar: Fern

As Fern skips out after Micah, Skyler turns to Vez.

VEZ: No.

SKYLER: I haven't even said anything yet!

VEZ: The answer is still no.

SKYLER: But I'm not asking a question! I just want to tell you that...
SKYLER: I've changed. I'm not the same shallow fame-seeker I was before.

{guitar_whalesong == "Human":
    VEZ: That guitar solo you busted out tonight begs to differ.

- else:
    VEZ: I can tell you're trying. I noticed that restrained guitar riff you played tonight.
    VEZ: But people who've changed don't just say, "I've changed."
}

VEZ: Besides, you know the real issue was never your love of the spotlight.

SKYLER: (sighs) I know, but I'm not like you. I don't know what "causes" to support!

VEZ: It's not a right or wrong answer. Not really. 
VEZ: But if you're in a band, you need to care about the world and what's happening in it, one way or the other. 

    + SKYLER: I don't know how to do that.
        SKYLER: Can you help me?
        
        VEZ: I can't make you care about stuff, Skyler. You need to take an interest in things outside of yourself.
        
        ++ SKYLER: But I do!
            -> TEST_SKYLER 
            
        ++ SKYLER: I'll try. 
            SKYLER: Guess I should start watching the news?
            
            VEZ: That'd be a good start. 
            -> ASK_VEZ
        
    + SKYLER: But I do care!
        -> TEST_SKYLER
        
= TEST_SKYLER
Vez asks a question that tests Skyler's knowledge about the whales' cause to be part of the Bandocracy.
Skyler fails it. She just hasn't been paying attention. But she gets Vez's point and promises to start taking an interest in what's going on in the world. 
    -> ASK_VEZ

= ASK_VEZ

SKYLER: I want to be a better person, bandmate, maybe even... friend?

VEZ: I'd like that too.

SKYLER: Great! Want to start by getting a drink or something? I know this place just around the corner.

    + VEZ: Sure, I could use a drink.
        ~ L0_drinks = true
        {vocals_whalesong == "Whaleish":
            VEZ: Singing in Whaleish is hard on the vocal cords.
            VEZ: So, lead the way!
        - else:
            VEZ: It's been a while since I performed in a big venue.
            VEZ: I forgot how thirsty I get.
            
            SKYLER: I'm always thirst-- Nevermind. Forget I was about to say that.
            SKYLER: Okay, so, follow me! 
        }
    + VEZ: Nope, I'm not falling for that again.
        ~ L0_drinks = false
        VEZ: Let's keep things professional between us.
        
        SKYLER: Aren't "professional drinks between colleagues" a thing?
        
        VEZ: Not with you they're not. Goodnight, Skyler.
    -
    
#RemChar: Vez
#RemChar: Skyler

    -> REWARD_SCREEN
    
=== REWARD_SCREEN ===

We've not designed this yet. Keana has a rough mock up on Miro. I think that if we end each level at a Reward Screen, we should start the new day with a brief SCENE in the Practice Space, rather than dropping players into the PLAYLIST, which is what it looks like now on the Miro board. 

    -> PRACTICE_L1