BloomDigital
/
Bandocracy-ink
5
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity

Mood Tattoos scenes added to script.

This commit is contained in:
Heather Jackson 2025-02-18 16:30:23 -05:00
parent 49115fa5ea
commit cf4b51c9a8
5 changed files with 1397 additions and 2 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

226
Level1/OUTCOME_MOODTATTOOS.ink Normal file
View File

@ -0,0 +1,226 @@
-> OUTCOME_MOODTATTOOS
=== OUTCOME_MOODTATTOOS ===
//HJ: I'm thinking this scene takes place a few days later, long enough for the political outcome to happen. And because the noise complaint letter comes regardless of the song the band performed, this scene can take place after either Whale Song or Mood Tattoo. We'll use variables to vary the text where needed.
#Environment: PracticeSpace
#PlayMusic: noodling
#AddChar: Singer, Pose: playing
#AddChar: Guitarist, Pose: playing
#AddChar: Bassist, Pose: playing
#AddChar: Drummer, Pose: playing
//HJ: IDEA! To get into this scene, maybe one of the characters enters while the others are noodling and tells them all that their first song made a difference! The excitement needed makes me think it'd probably be Keys.
#AddChar: Keyboardist, Pose: excited
#StopMusic: noodling
#AddChar: Singer, Pose: neutral
#AddChar: Guitarist, Pose: neutral
#AddChar: Bassist, Pose: neutral
#AddChar: Drummer, Pose: neutral
The band has had an impact.
{vocals_moodtattoo == "Whaleish":
KEYBOARDIST informs the band that as many people got mood tattoos THAT NIGHT than had gotten them all year. The city is reporting a drop in coffee shop arguments and other small tense interactions that all lead up to a bad day!
Bassist points out that a few local business leaders were goaded into accepting them, as well, and have already been exposed as liars. So...good job, band.
- else:
Guitarist says mood tattoo interest has plummeted, with people wondering who is really behind them and what else those people might want.
KEYBOARDIST is worried about that distrust, and thinks that people already feel more suspicious.
SINGER knows that this SEEMS worse, but people should always ask questions.
}
Oh! And the band also got this old-fashioned, hand-written letter. Keys found it outside the door. It's a... noise complaint! About their first performance!
Bassist admits they're kinda thrilled the band's first song warranted a noise complaint.
Keys, who wasn't sure how to react to a noise complaint, follows Bassist's lead - the band's debut made such a spash it riled people up! Cool!
Bassist reads the letter aloud. It's from The Unvoiced, who feel like they were SUBJECTED to an unwanted vocal performance by {band_name}.
The other performances were instrumental or electronic...but no one said we couldn't sing! Why did they come?
//MK: You didn't mention when to reveal it, and it was used as Singer's secret in your Miro, so I'll put it here....
Singer admits they know that the Unvoiced created Mood Tattoos. That's why they were there.
//MK: Does feel a bit clunky, though. We should massage the Unvoiced secret.
{
- vocals_moodtattoo == "Whaleish":
That explains why they're saying we "are trying to destroy the beauty of non-verbal communication and encourage verbal conflict".
SINGER shrugs - that was the whole point. They should be happy we didn't call them out by name.
- vocals_moodtattoo == "Human":
Well, they're still mad about our vocals. Even though we supported mood tattoos, we "reduced them to a simplistic mood-ring equivalent fad".
Oh, well. The crowd loved it. And they may not have, had SINGER named The Unvoiced.
}
Singer wants to see the letter.
KEYBOARDIST asks why Singer kept that secret. Why wouldn't they tell the band about the Unvoiced creating mood tattoos? And how did they even know?
Singer looks at the letter.
SINGER: recognizes Mom's handwriting... should I tell the others? #PRIVATE
+ SINGER: Tell bandmates my Mom wrote this. #PRIVATE
-> SINGER_REVEALS_MOM
+ SINGER: Don't tell them anything. #PRIVATE
-> SINGER_KEEPS_MOM_SECRET
= SINGER_KEEPS_MOM_SECRET
Singer claims they'd just heard about it somewhere.
//MK: I tried to keep the structure from the Whale Song scene so we could keep Guitar outing Singer's mom. In this world, I think Singer would do that if they felt like Singer "forced" them into supporting mood tattoos as a weak attempt to make things up to mom. Mean! If it doesn't work for you, it can just come out.
{
- (arc_guitarist == "egocentric") && (vocals_moodtattoo == "Human")://MK:
GUITARIST: From someone in the Unvoiced? Your mom, maybe?
Bassist guesses who Singer's mom is.
Singer confirms it, and lashes out at Guitarist for revealing it like that.
~ band_knows_about_singer_mom = true
-> SINGER_MOM_FEELS
- arc_guitarist == "humbled":
GUITARIST asks if Singer is okay.
Singer admits that they recognize the handwriting in the letter. It's from mom. Guitarist agrees to keep the secret.
- else:
GUITARIST asks if the complaint mentions the guitar, or did the Unvoiced love it like everyone else?
}
Singer retreats into their own head for a private thought...
+ SINGER: Maybe this noise complaint is Mom's way of reaching out. #PRIVATE
~ arc_singer = "hopeful"
+ SINGER: Even after all these years, Mom can't resist scolding me. #PRIVATE
~ arc_singer = "bitter"
-
-> BASSIST_IMPRESSED
= SINGER_REVEALS_MOM
~ band_knows_about_singer_mom = true
Singer admits to the band that the letter is in their Mom's handwriting.
{
- (arc_guitarist == "egocentric") && (vocals_moodtattoo == "Human"):
GUITARIST asks if this whole thing was just to apologize to mom for leaving her cult. Looks like it didn't work.
SINGER explains THIS is why they didn't say anything earlier...because GUITARIST would make it personal.
- arc_guitarist == "humbled":
GUITARIST asks if SINGER is okay. It's been a while since they'd last heard from mom.
SINGER says they don't know, yet.
- else:
GUITARIST Well...at least guess she liked the guitar...
}
Bassist guesses who SINGER'S mom is. They understand keeping that secret. It's SINGER'S business.
KEYBOARDIST doesn't know who S's mom is, but is glad she didn't stop SINGER from singing.
-> SINGER_MOM_FEELS
= SINGER_MOM_FEELS
...but how does Singer feel?
+ SINGER: Hopeful. Maybe this noise complaint is Mom's way of reaching out.
~ arc_singer = "hopeful"
+ SINGER: Bitter. Even after all these years, Mom can't resist scolding me.
~ arc_singer = "bitter"
-
-> BASSIST_IMPRESSED
= BASSIST_IMPRESSED
Bassist reiterates that getting a noise complaint is a win. It means the song's message had impact!
{arc_guitarist == "humbled":
Guitarist backs up Bassist's sentiment and supports Singer, agreeing that so far Singer is leading the band well.
- else: //egocentric
Keys agree with Bassist, but Guitarist is silent.
Singer notices Guitarist being pouty.
}
Singer thanks them for the kind words, being super modest about it, but Bassist isn't done...
Bassist admits that Singer is the reason they joined this band, which will be their last band, one way or another.
{vocals_moodtattoo == "Whaleish":
Singer has the confidence to laugh off the pressure.
- else:
Singer feels the full weight of Bassist's expectations.
}
DRUMMER: ...reminds everyone that they're renting this practice space. Are we gonna practice? Write a song?
Sure. Band starts getting ready.
{arc_guitarist == "humbled":
Guitarist pulls Singer aside.
-> CONVO_SINGER_GUITAR_HUMBLE
- else: //"egocentric"
Singer pulls Guitarist aside.
-> CONVO_SINGER_GUITAR_EGO
}
= CONVO_SINGER_GUITAR_HUMBLE
Guitar reassures Singer that this band is going to be different, they are different now.
Singer shares that they did notice Guitar making an effort, but they were still a bit fixated on what they wanted, personally.
-> CONVO_KEYS_BASSIST
= CONVO_SINGER_GUITAR_EGO
Singer asks what the hell that was about?
{
- (arc_guitarist == "egocentric") && (vocals_moodtattoo == "Human"):
Guitarist accuses Singer of forcing them into a pro-tattoo stance just to get a message out to mom. Now G is stuck supporting something they don't believe in. again!
Singer swears it wasn't the case. This was not about mom.
- else:
Guitarist apologizes profusely. They're frustrated about critics and took it out on Singer.
}
Singer accepts G's apology, but worries they're just in this band for themselves.
-> CONVO_KEYS_BASSIST
= CONVO_KEYS_BASSIST
Uncharacteristically, Guitar is silent, not sure yet how to respond to Singer. Camera focus shifts to...
BASSIST and KEYBOARDIST discuss their differing views on hope. Keys doesn't understand anyone losing hope in anything. Bass explains that they felt that way once, but now...they're retiring. This band is their last kick at the can. No matter what.
Keys wonders if Bass gave up hope too soon...even if it happened years ago. What changed? Bass explains - nothing. That's the problem - people don't change. No matter what your music says.
Keys isn't sure about what the music said...
{vocals_moodtattoo == "Human":
The song was fun...but the cause just didn't seem big enough.
- else:
The song they played was just too negative.
}
Maybe this band isn't the right fit...
Bass explains that they won't be 100% onside with everything, but if they quit everything at the first sign of trouble, they'll never feel like they're part of something.
You should only quit after a long career drains the energy out of you. That's a joke. Keys laughs.
-> CONVO_SINGER_GUITAR
= CONVO_SINGER_GUITAR
{vocals_moodtattoo == "Human":
Guitar admits - they're worried about revealing their true feelings with a mood tattoo. What if they haven't truy changed? But they just played a song encouraging people to GET them! Doesn't THAT make them a fraud anyway?
Guitar thinks that G is only a fraud if they lie about what they feel. Do they feel badly because of what they did, or because they got caught?
- else: //"Rebels"
Guitar expresses frustration with the critic who called them out. Will they have to carry past mistakes forever? What do people want from them?
Singer suggests it's more about what Guitar wants from themself. Do they want to change, or just forget about the past?
}
+ GUITARIST: gets defensive and wonder if Singer will ever be happy, or if they just want to judge them forever.
~ arc_guitarist = "egocentric"
+ GUITARIST: admit that they aren't sure, yet. That's part of their problem.
~ arc_guitarist = "humbled"
-
Guitar is still searching for what they truly believe in. They're a work in progress. So, maybe, we should go out for a drink and talk about it.
+ SINGER: Accept drink invite.
Maybe Guitarist really is trying and Singer can help.
+ SINGER: Refuse invite.
No way is Singer letting Guitarist drag them back into that relationship.
-
-> SONG_TOPICS_L2

5
Level1/PERFORMANCE_MOODTATTOOS.ink Normal file
View File

@ -0,0 +1,5 @@
-> PERFORMANCE_MOODTATTOOS
=== PERFORMANCE_MOODTATTOOS ===
-> POST_PERFORM_MOODTATTOOS

348
Level1/POST_PERFORM_MOODTATTOOS.ink Normal file
View File

@ -0,0 +1,348 @@
-> POST_PERFORM_MOODTATTOOS
=== POST_PERFORM_MOODTATTOOS ===
#Environment: van
#AddChar: Singer, Pose: neutral
#AddChar: Guitarist, Pose: neutral
#AddChar: Bassist, Pose: neutral
#AddChar: Keyboardist, Pose: neutral
#AddChar: Drummer, Pose: neutral
//MK: I'm not convinced that Singer would speak first if they'd switched lyrics, I gave this to Akai. If we're saying that the performance always goes well in the room, Singer could start this because they want to say "see? It worked!" So, I gave this to Akai for the moment.
DRUMMER: LET'S GET WASTED!
SINGER: I think Akai means "great first show!"
{
- (song_stance_L1 == "Human") && (vocals_whalesong == "Whaleish"):
KEYBOARDIST is sad and disappointed in SINGER for singing against Mood Tattoos.
-> DISSENT_STANCE_WHALEISH
- (song_stance_L1 == "Whaleish") && (vocals_whalesong == "Human"):
GUITAR is angry. They had to suck it up and play, but SINGER can just do whatever they want.
-> DISSENT_STANCE_HUMAN
- else:
DRUMMER: I would never say you were great. But the crowd did love it.
~ band_unity++
{WHALESONG_JAM.DISSENTER_SINGER: -> DISSENTER_STANCE_SWITCH | -> BAND_VISION_CHECK}
}
= DISSENTER_STANCE_SWITCH
BASSIST: Hey, {name_singer}. Thanks for singing the lyrics we agreed on.
BASSIST: Even if you didn't want to.
-> BAND_VISION_CHECK
= DISSENT_STANCE_WHALEISH
~ band_unity-- //Dissent automatically knocks down band unity. Only the players' choices can bring it back up, or knock it down farther.
BASSIST likes the lyrics, but doesn't like not trusting SINGER...
//NOTE: Give players PRIVATE choices where the other players just see " . . . " above their heads until they make their choice. Not sure if this is the command we'll use in game, but for now, this command clearly shows how we see this working. I, at least, think this is a good example of Private Choices being the best option, rather than Public Choices.
+ SINGER: I know I made the right choice. #PRIVATE
SINGER had to be true to their conscience. No matter what.
+ SINGER: I shouldn't have done that. #PRIVATE
SINGER: I did what I believed in most, but that's not the point.
SINGER: We agreed. And we need to be able to trust each other. I'm sorry.
-
~ temp mood = 0
+ BASSIST: I can accept that. #PRIVATE
BASSIST: We all think this sucks, but I'm good to put it behind us.
~ mood++
+ BASSIST: {name_singer} is full of shit. #PRIVATE
BASSIST: If you pull this shit again, I'm gone. //MK: not sure if we can do this, but it makes sense for the character in this case. WhaleSong works regardless of stance. This song has two different messages.
~ mood--
-
//HJ: I'm hoping we can keep this really short - 1 response line said aloud just to voice opinion and move on to the next character. Don't make this a full-fledged argument or debate. What happened happened, and this is just a moment for each character to say their piece and influence band unity.
Guitarist's turn.
+ GUITARIST pretends to be mad, even though they're relieved.
~ mood++
+ GUITARIST is actually upset. They didn't know they could all just do what they want. They'll remember that.
~ mood--
-
/*
HJ: Because Keys is less confrontational, I thought we'd make Keys the reaction character. So Keys doesn't get a secret choice in this scene, but how the others responded above (tracked by temp variable) will influence Keys' response. If it's a mood "tie" b/w Bassist and Guitarist, Keys will break it towards the positive and add a +1 to band unity, effectively nullifying the -1 at the start of this stitch. If both Bassist and Guitarist responded positively to Singer, Keys adds to that. +2 to unity! But if Guitarist and Bassist were both negative, take -2 off unity.
NOTE: The point of using the temp variable instead of adding/subtracting band_unity on Bassist/Guitar's responses is that we can't be sure what value band_unity started at. Whereas we know the temp variable started at 0.
*/
{
- mood == 0: //Bassist and Guitarist had opposite responses and cancelled each other out
KEYBOARDIST thinks it's best for the band to just move on. The song still went over.
~ band_unity +=1
- mood == 2: //mood is positive
KEYBOARDIST is willing to be happy if everyone else is.
~ band_unity +=2
- else: //mood is negative
KEYBOARDIST can't help but say it - SINGER is on their own. And doesn't speak for the rest of them.
~ band_unity -=2
}
-> BAND_UNITY_CHECK
= DISSENT_STANCE_HUMAN
~ band_unity--
//MK: Guitar has just confronted SINGER
+ SINGER: I know I made the right choice. #PRIVATE
SINGER had to be true to their conscience. No matter what.
+ SINGER: I shouldn't have done that. #PRIVATE
SINGER: We agreed. And we need to be able to trust each other. I'm sorry.
-
~ temp mood = 0
BASSIST jumps in...
+ Like the change. #PRIVATE
Smooths things over. The song was a pop success...and GUITARIST doesn't have to get a tattoo. BASSIST won't, either.
~ mood++
+ Dislike surprises #PRIVATE
GUITARIST was a professional just to keep playing. Maybe we should have stopped on principle.
~ mood--
-
+ GUITARIST: Be the bigger person. #PRIVATE
Says they'll be the one to rise above their petty personal feelings. Damn!
~ mood++
+ GUITARIST: this is already personal #PRIVATE
They didn't know they could all just do what they want. They'll remember that.
~ mood--
-
-> BAND_UNITY_CHECK
//NOTE: If band went into the performance with the highest unity score of +4 , but made all the negative choices in these dissenter stitches, the highest score they could have now is +1 , which is why that is the number we're checking against in the stitch below...
= BAND_UNITY_CHECK
{band_unity <= 1:
DRUMMER: Well, I didn't think you'd break up after your first song.
DRUMMER: But you're close. Very close. //MK: I wonder about talking about band unity in a way that highlights its metric nature. But maybe this line doesn't work.
- else:
DRUMMER: Congratulations! You've survived your first band betrayal.
KEYBOARDIST: That's the power of positivity!
}
+ SINGER: I'm glad that worked out. #PRIVATE
//HJ: I know there are a LOT of different ways the dissenting scenes could have played out, but this choice's main purpose is to set Singer's mood variable, so keep the choice lines super general.
+ SINGER: That was a mistake. #PRIVATE
-
-> BAND_VISION_CHECK
= BAND_VISION_CHECK
BASSIST is surprised. They have a review. Others are surprised that Bass even pays attention to reviews...//MK: Can/should we attribute the review to someone? This city's version of NOW Magazine?
{vocals_whalesong == "Whaleish":
BASSIST: The Upgraders didn't like the song. It was like a technophobe conspiracy screed from the Old World.
KEYBOARDIST: The song made the All For All fans cancel their mood tattoos and book appointments to talk to their therapists instead. Therapy is good...but couldn't everyone just do both?
GUITARIST has good news and bad news. Bad news is that the tattoo guys are pretty mad because no one is getting a Mood Tattoo. Good news is that the audience all want anti-corporate traditional ink. So that's good.
SINGER has the same - the venue is mad and banned up because we went against the WHOLE POINT of the show...but doing that is really badass, so we're cool again.
- else:
BASSIST: The Upgraders loved the song. They see tattoos as the first step to human/machine integration and are happy for the support. Not where BASSIST was thinking this would go....but cool.
KEYBOARDIST: the All for All folks all got mood tattoos during the show, and now they're glowing! The selfies are cool.
SINGER is praised for "uncharacteristic" fluffy positivity. They don't know how to feel about that.
}
//MK: I left everything in here, just in case you wanted to do anything with it, but I imagine this is where the stitch ends, we count this outcome, and we go to FAN REACTIONS.
{
- (band_vision == band_stance_L1) && (song_stance_L1 == vocals_whalesong):
Great! They're the kind of band they set out to be!
- (band_vision != band_stance_L1):
{band_vision == "People":
If they really wanted to be a Band of the People, they should have stuck to human-only lyrics.
- else: //"Rebels"
If they really wanted to be a Band of Rebels, they should have had lyrics in Whaleish!
}
- (band_vision == band_stance_L1) && (song_stance_L1 != vocals_whalesong):
//Vision and stance match, but the vocals don't, meaning Singer dissented and chose the other lyrics - and that's what the critic heard.
The critics have gotten the wrong idea about what kind of band they are, and it's Singer's fault!
}
//HJ: I sent ALL the options here, even the ones that match, because this seems like a pretty important piece of info that will affect the end song.
But why does band vision even matter?!
Briefly establish that it matters because fans, critics and everyone now have expectations of {band_name} based on this first song.
After all, in the 22nd century, aspiring bands aren't merely writing songs to get on billboard charts; they're writing songs with a vision for governing the world!
If you flip-flop on your vision, well, nobody will trust you.
So, you still want to be a {band_vision == "People": Band of the People?|Band of Rebels}?
Akai lets them know they won't be able to change their band vision again. This is it.
//HJ: I want players to have the opportunity to change their mind JUST THIS ONCE now that they know how band vision affects performance, but don't want it to be a vote. We can let the players discuss amongst themselves in real life, then the Host Player selects the choice they decide on.
+ [Don't change it.]
DRUMMER: 1-line comment on this decision
-> FAN_REACTIONS
+ [Change band vision.]
-> CHANGE_VISION
= CHANGE_VISION
{band_vision == "People":
~ band_vision = "Rebels"
- else:
~ band_vision = "People"
}
SINGER: Well, we definitely got noticed.
DRUMMER: Yes, you did.
{vocals_whalesong == "Whaleish":
Akai points out that not all the attention is positive...
- else:
Akai tells them they've been offered free mood tattoos.
}
-> FAN_REACTIONS
= FAN_REACTIONS
#PlaySFX: Akai_excited
DRUMMER: THERE IS NO ENCORE!
DRUMMER: (sigh) Time to pack up and go.
//NOTE: The team doesn't have time to design a social media interface for the CMF demo, so what I've done here is just split the characters out into their own screens and we'll write this as if they're on their devices reading the comments.
#SPLITFLOW
{
- char_singer:
{vocals_whalesong == "Whaleish":
-> SINGER_SOCIALS_NO_TATTOO
- else:
-> SINGER_SOCIALS_YES_TATTOO
}
- char_guitarist:
{
- vocals_whalesong == "Whaleish":
-> GUITARIST_SOCIALS_NO_TATTOO
- else:
-> GUITARIST_SOCIALS_YES_TATTOO
}
- char_bassist:
{
- vocals_whalesong == "Whaleish":
-> BASSIST_SOCIALS_NO_TATTOO
- else:
-> BASSIST_SOCIALS_YES_TATTOO
}
- char_keyboardist:
{
- vocals_whalesong == "Whaleish": //If Keys played whaleish harmonics
-> KEYS_SOCIALS_NO_TATTOO
- else:
-> KEYS_SOCIALS_YES_TATTOO
}
}
= SINGER_SOCIALS_NO_TATTOO
SINGER reads as HushPuppie, one of the Unvoiced, calls them out for 'closed-minded' and 'voca-centric' lyrics.
+ [Defend the song.]
SINGER counters. They delivered an important message - resist and suspect anything that can silence you. If the song wasn't for you, so be it.
+ [Attack the Unvoiced.]
SINGER lashes out at the poster, and the Unvoiced. Closed-minded is rejecting and exiling people WHO SPEAK.
-
-> LEAVE_VENUE
= SINGER_SOCIALS_YES_TATTOO
SINGER is offered a mood tattoo because they've fostered togetherness and emotional connection.
SINGER is glad they've encouraged those things, but...
+ [Decline, politely.]
SINGER says they'd rather connect with song. Words are their tool, and they're indispensable.
+ [Refuse, bluntly.]
SINGER, frustrated, outs the tattoos as an Unvoiced creation, and the Unvoiced are the opposite of everything they are.
+ [Don't respond.]
SINGER doesn't want their refusal to reflect on the band.
-
-> LEAVE_VENUE
= GUITARIST_SOCIALS_NO_TATTOO
A reviewer points out that while GUITARIST didn't believe in anything with the Politicats, and now they've moved up to believing in NOT doing something. Is that better?
GUITARIST bristles at this, but this is what they feared would happen...
+ [Ignore them.]
GUITARIST puts their phone down> It'll just look worse if they stand up for the band. Ignore it, and no one will remember it.
~ arc_guitarist = "egocentric"
+ [Defend yourself.]
Of course it's better. The tattoos are a harmful fad, and we spoke out against them. Yeah, I believe in not doing something just because people want you to.
~ arc_guitarist = "humbled"
-
-> LEAVE_VENUE
= GUITARIST_SOCIALS_YES_TATTOO
GUITARIST is offered a mood tattoo to enhance their onstage persona. Think of it as a personal light show. They don't want one, but they feel like they can't refuse...
+ [Book a tattoo appointment!]
GUITARIST promises to get a tattoo as soon as possible!
They've changed. Maybe this will help them...stay changed?
~ arc_guitarist = "humbled"
+ [Put it off.]
GUITARIST promises to check their schedule and make it happen soon.
They don't intend to follow through. They don't want to risk looking bad.
~ arc_guitarist = "egocentric"
-
-> LEAVE_VENUE
= BASSIST_SOCIALS_NO_TATTOO
BASSIST is asked by conspiracy fans what they know. Is there REALLY something going on? Who's behind it? //MK: this would work better if B knew the Unvoiced was involved, and decided not to say because it's Singer's business.
+ [Who cares? It's a song.]
BASSIST says that everything is connected and corrupt. But it doesn't matter - people just want new shit. Now they have a new song.
~ arc_bassist = "cynical"
+ [Confirm conspiracy.]
BASSIST says that, obviously, whoever makes the tattoos will use whatever information they can get from you. No matter who they are - do you really want any company to know how you feel all the time? No. We can stop this.
~ arc_bassist = "hopeful"
-
-> LEAVE_VENUE
= BASSIST_SOCIALS_YES_TATTOO
BASSIST mulls it over. Do they want one?
+ [No.]
BASSIST thinks it's better if people don't see their mood all the time.
~ arc_bassist = "cynical"
+ [Yeah, sure.]
BASSIST stipulates that it be somewhere that isn't always exposed. They need their mystery.
~ arc_bassist = "hopeful"
-
-> LEAVE_VENUE
= KEYS_SOCIALS_NO_TATTOO
KEYBOARDIST is challenged to get a mood tattoo before they judge. Yeah...that makes sense. They didn't want to take this stance, anyway.
+ [Accept the challenge.]
KEYBOARDIST is willing to get a mood tattoo!
~ arc_keyboardist = "chearlead"
+ [Admit you love mood tattoos.]
KEYBOARDIST says that THE BAND is judging. They, personally, love mood tattoos.
The band needs to cheer up!
~ arc_keyboardist = "police"
-
-> LEAVE_VENUE
= KEYS_SOCIALS_YES_TATTOO
KEYBOARDIST absolutely wants a tattoo. Their parents would not approve. They're too young. //MK: What are is the cutoff in this game's future? Everyone is pro-tattoo already these days.
+ [Accept and lie about age.]
They'll get one ASAP...but they may have to hide it. But, this will help them put positivity into the band.
~ arc_keyboardist = "chearlead"
+ [Get back to them in a year.]
They're honest about their age, but will be there on their next birthday!
They'll have to manage the band's vibe without it.
~ arc_keyboardist = "police"
-
-> LEAVE_VENUE
= LEAVE_VENUE
#REJOIN
With that, they all exit. First performance is done!
-> OUTCOME_MOODTATTOOS

811
Level1/PRACTICE_MOODTATTOOS.ink
View File

@ -1,3 +1,812 @@
=== PRACTICE_MOODTATTOOS === === PRACTICE_MOODTATTOOS ===
KEYBOARDIST thinks the band should get mood tattoos for the show! Smiley faces! Or a happy sun?!
-> END GUITARIST points out that Keys is assuming the band is pro-tattoo.
KEYBOARDIST wants to encourage people to get them - for deeper connections and fewer conflicts.
SINGER concedes that data suggest people with tattoos are less prone to conflict...but there's more to communication than moods. WORDS are important, and the tattoos take the place of words.
BASSIST says People can lie with words. They CAN'T lie if people know what they're feeling. If someone is full of shit, everyone will see it. That's good.
GUITARIST thinks people have the right to keep secrets if they want to. Like onstage, where you may put on a face for the crowd. What matters is what you put out there, not what's inside.
KEYBOARDIST suggests you could also show people that you aren't hiding ANYTHING. Guitar hadn't thought of it that way.
They'll vote on it.
AKAI triggers the vote...
#SPLITFLOW
{
- char_singer:
-> SINGER_THOUGHTS
- char_guitarist:
-> GUITARIST_THOUGHTS
- char_bassist:
-> BASSIST_THOUGHTS
- char_keyboardist:
-> KEYBOARDIST_THOUGHTS
}
= SINGER_THOUGHTS
SINGER knows that the tattoos were created by The Unvoiced, but worries about bringing that up. Keys and Bass don't know about their mom.
-> VOTE_TIME
= GUITARIST_THOUGHTS
GUITARIST knows they've changed. But what if they're lying to themselves? They don't want to risk finding that out along with everyone else...and knowing they are't capable of change.
-> VOTE_TIME
= BASSIST_THOUGHTS
Warning people away from these tattoos seems paranoid. They're kinda silly but who cares?
BASSIST wonders why Singer is so strongly against the tattoos. Maybe there's a conspiracy they want to blow up. Maybe that sounds fun...
-> VOTE_TIME
= KEYBOARDIST_THOUGHTS
KEYBOARDIST isn't old enough to get a mood tattoo. They'd lie about it...but don't want to lie!
-> VOTE_TIME
= VOTE_TIME
#REJOIN
#PlayerControlUntil: VoteComplete, JumpToPath: PRACTICE_whalesong.VOTE_RESULTS
+ [VOTE ON IT!]
-> VOTE
= VOTE
{
- char_singer:
-> VOTE_SINGER
- char_guitarist:
-> VOTE_GUITARIST
- char_bassist:
-> VOTE_BASSIST
- char_keyboardist:
-> VOTE_KEYBOARDIST
}
= VOTE_SINGER
+ [Get a Mood Tattoo!]
~ vote_songstance_human++
+ [Don't Get a Mood Tattoo!]
~ vote_songstance_whaleish++
-
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
-> VOTE_RESULTS
= VOTE_GUITARIST
+ [Get a Mood Tattoo!]
~ vote_songstance_human++
+ [Don't Get a Mood Tattoo!]
~ vote_songstance_whaleish++
-
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
-> VOTE_RESULTS
= VOTE_BASSIST
+ [Get a Mood Tattoo!]
~ vote_songstance_human++
+ [Don't Get a Mood Tattoo!]
~ vote_songstance_whaleish++
-
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
-> VOTE_RESULTS
= VOTE_KEYBOARDIST
+ [Get a Mood Tattoo!]
~ vote_songstance_human++
+ [Don't Get a Mood Tattoo!]
~ vote_songstance_whaleish++
-
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
{shuffle:
-
~ vote_songstance_human++
-
~ vote_songstance_whaleish++
}
-> VOTE_RESULTS
= VOTE_RESULTS
{
- vote_songstance_human == 4:
~ band_unity +=2
-> STANCE_COMEGET
- vote_songstance_human == 3:
~ band_unity +=1
-> STANCE_COMEGET
- vote_songstance_whaleish == 4:
~ band_unity +=2
-> STANCE_DONTGET
- vote_songstance_whaleish == 3:
~ band_unity +=1
-> STANCE_DONTGET
- else:
{not TIE_RULES: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE } //If players have not heard the TIE RULES, go there in the event of a tie vote. Otherwise, players already know the rule is Drummer's Choice.
}
= TIE
~ vote_songstance_human = 0
~ vote_songstance_whaleish = 0
//Reset votes ^ and send players back to VOTE...
#PlayerControlUntil: VoteComplete, JumpToPath: PRACTICE_whalesong.VOTE_RESULTS
+ [Vote again!]
-> VOTE
= DRUMMER_CHOICE
~ band_unity-- //band couldn't agree, so band unity drops.
Akai has to break the tie. This would be awkward if they had their tattoos already...
{shuffle:
-
-> STANCE_COMEGET
-
-> STANCE_DONTGET
}
= STANCE_COMEGET
DRUMMER: You're telling people to Come Get a Mood Tattoo!
~ band_stance_L1 = "People"
~ song_stance_L1 = "Whaleish"
/*NOTE: I created 2 variables in order to...
1) compare band_stance to band_vision to see if they're equal or not, and thus these variables need the same values, "Rebels" or "People".
2) compare song_stance_L1 to vocals_whalesong, the same way as above, using the values "Whaleish" or "Human".
*/
#SPLITFLOW
{
- char_singer:
-> SINGER_FEELS_COMEGET
- char_guitarist:
-> GUITARIST_FEELS_COMEGET
- char_bassist:
-> BASSIST_FEELS_COMEGET
- char_keyboardist:
-> KEYS_FEELS_COMEGET
}
= SINGER_FEELS_COMEGET
+ [I can't do that.]
SINGER doesn't want to sing something they don't believe in. They don't even think they CAN. #THOUGHT
+ [I'll make this my own.] //MK: I'm thinking this can be a choice reaction, but it's still not really going to work out later...
SINGER vows to promote the tattoos as a benefit, rather than the verbal substitute The Unvoiced intended. #THOUGHT
-
{DRUMMER_CHOICE:
SINGER wonders if they should have rigged this vote. #THOUGHT
}
-> MOODTATTOOS_STEMS
= GUITARIST_FEELS_COMEGET
//MK: Guitar didn't want tattoos, but waffled a bit
{DRUMMER_CHOICE:
GUITARIST wonders what the robot version of the tattoos would be.
}
+ [Negative.]
If he flashes (blinks?) insincerity, this comeback is over.
+ [Reluctant but resolute]
Fine. I can always refuse to get one...
-
-> MOODTATTOOS_STEMS
= BASSIST_FEELS_COMEGET
+ [This'll be great.]
Hopes every bullshit artist will get one.
+ [Neutral.]
Wonders if Singer could have pulled off a paranoia anthem....
-
{DRUMMER_CHOICE:
BASSIST: Akai wants humans to do this so they can't lie to bots anymore.
}
-> MOODTATTOOS_STEMS
= KEYS_FEELS_COMEGET
+ [Yes!]
If you're happy and you know it, we will also know it!
+ [Neutral.]
They can't lie, they really wish everyone was super positive about it.
-
{DRUMMER_CHOICE:
KEYBOARDIST: I'm glad Akai can choose, so we don't start fighting.
}
-> MOODTATTOOS_STEMS
= STANCE_DONTGET
DRUMMER: Tell people NOT to get a mood tattoo!
~ band_stance_L1 = "People"
~ song_stance_L1 = "Human"
#SPLITFLOW
{
- char_singer:
-> SINGER_FEELS_DONTGET
- char_guitarist:
-> GUITARIST_FEELS_DONTGET
- char_bassist:
-> BASSIST_FEELS_DONTGET
- char_keyboardist:
-> KEYS_FEELS_DONTGET
}
= SINGER_FEELS_DONTGET
+ [That's a relief.]
SINGER didn't want to sing something they didn't feel. #THOUGHT
+ [Excited]
Wants to hit back at the Unvoiced.
+ [Worried it's too negative.]
Knows the song will still have to be FUN.
-
-> MOODTATTOOS_STEMS
= GUITARIST_FEELS_DONTGET
//MK: again - I think Guitarist is waffling.
+ [Feels safe.] //MK: maybe this is redundant...
+ [What if I HAVE changed?]
Maybe this could have shown it...
+ [Safe...but this won't be a hit.] //MK: I think this is better. They'd feel relived, but a bit concerned about a negative song bringing people down.
Telling people not to do something is never popular.
-
-> MOODTATTOOS_STEMS
= BASSIST_FEELS_DONTGET
+ [This song is pointless.]
Why make a song telling people to do nothing?
+ [Trust singer's approach.]
They must have something to expose. Right?
-
{DRUMMER_CHOICE:
BASSIST - Akai must think human problems are stupid.
}
-> MOODTATTOOS_STEMS
= KEYS_FEELS_DONTGET
+ [This is the WORST.]
They aren't in the band to preach negativity.
+ [Will get a tattoo anyway!]
They'll know how unhappy I am! Which is good because I don't want to say it!
-
{DRUMMER_CHOICE:
KEYBOARDIST thinks Akai would want a cool mood indicator light.
}
-> MOODTATTOOS_STEMS
=== MOODTATTOOS_STEMS === //MK: so, what you have on the Miro for each character is good, so rather than put it in place for the outline, I left a description of the general feeling they'd have about each one.
#REJOIN
DRUMMER: The message is simple. The beats should be simple, too.
DRUMMER: We can get people dancing...
#PlayMusic: drums_whalesong_comeget
DRUMMER: Or, we can go all minimalist...
#PlayMusic: drums_whalesong_dontget
{song_stance_L1 == "Whaleish":
//MK: went with what they're feeling would be based on how the stem actually sounds. Included Singer here because they don't like this stance. Tried leaving Guitar on the outside this time, since they're only worried about themselves.
KEYBOARDIST loves the dancey track.
SINGER wonders if it should sound like a party - that's a bit like a commercial, isn't it?
BASSIST thinks an ominous track makes it sound like they're inviting people into a deadly trap. Weird.
- else:
KEYBOARDIST wants to avoid the ominous minimalist beat. Too dark!
BASSIST thinks if you're going dark, you should go dark. Don't play both sides.
SINGER could like the idea of scaring people away OR could think a "don't so it" song could still be fun.
}
GUITAR just wants this one to get done. (or, I think, may want this song to float under the radar. At least in this moment. See below...)
#PlayerControlUntil: VoteComplete, JumpToPath: MOODTATTOOS_STEMS.VOTE_RESULTS
+ [VOTE ON THE BEAT!]
-> VOTE_DRUMS
= VOTE_DRUMS
{
- char_singer:
-> VOTE_SINGER
- char_guitarist:
-> VOTE_GUITARIST
- char_bassist:
-> VOTE_BASSIST
- char_keyboardist:
-> VOTE_KEYBOARDIST
}
= VOTE_SINGER
+ [Minimalist.]
~ vote_whalesong_drums_whaleish++
+ [Dance Track.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_GUITARIST
+ [Minimalist.]
~ vote_whalesong_drums_whaleish++
+ [Dance Track.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_BASSIST
+ [Minimalist.]
~ vote_whalesong_drums_whaleish++
+ [Dance Track.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_KEYBOARDIST
+ [Minimalist.]
~ vote_whalesong_drums_whaleish++
+ [Dance Track.]
~ vote_whalesong_drums_human++
-
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
{shuffle:
-
~ vote_whalesong_drums_whaleish++
-
~ vote_whalesong_drums_human++
}
-> VOTE_RESULTS
= VOTE_RESULTS
{
- vote_whalesong_drums_whaleish >= 3:
DRUMMER: Votes are in and it's...
~ drums_whalesong = "Whaleish"
-> DRUMS_WHALEISH
- vote_whalesong_drums_human >= 3:
DRUMMER: Votes are in and it's...
~ drums_whalesong = "Human"
-> DRUMS_HUMAN
- else:
{not TIE_RULES: -> TIE_RULES -> TIE | -> DRUMMER_CHOICE } //If players have not heard the TIE RULES, go there in the event of a tie vote. Otherwise, players already know the rule is Drummer's Choice.
}
= TIE
~ vote_whalesong_drums_whaleish = 0
~ vote_whalesong_drums_human = 0
//Reset votes ^ and send players back to VOTE...
#PlayerControlUntil: VoteComplete, JumpToPath: MOODTATTOOS_STEMS.VOTE_RESULTS
+ [Vote again!]
-> VOTE_DRUMS
= DRUMMER_CHOICE
DRUMMER: I got this.
{shuffle:
-
~ drums_whalesong = "Whaleish"
-> DRUMS_WHALEISH
-
~ drums_whalesong = "Human"
-> DRUMS_HUMAN
}
= DRUMS_WHALEISH
DRUMMER: Drum level minimum. Beep.
-> CHOOSE_MUSIC_STEMS
= DRUMS_HUMAN
DRUMMER: LET'S DANCE!
-> CHOOSE_MUSIC_STEMS
= CHOOSE_MUSIC_STEMS
DRUMMER: Well. I've done my part...
DRUMMER: ...entering Sleep Mode.
SINGER: Rude. I guess it's our turn, now.
#SPLITFLOW
//Players go into private screens to play their musical parts and decide which to choose.
{
- char_singer:
-> VOCAL_STEMS
- char_guitarist:
-> GUITAR_STEMS
- char_bassist:
-> BASS_STEMS
- char_keyboardist:
-> KEYS_STEMS
}
//HJ: When the players choose to play a stem, a line of dialogue will pop up about how the character feels about this music stem. I've filled in these lines because I rewrote this part back in November to get my head around them, but feel free to revise so they fit the characters' voices better.
//NOTE: UI/UX for this just has 2 buttons on screen, with a dialogue bubble. For it to make sense in ink, I wrote it like this, but we'll need to actually talk about how the engine needs to interpret this section.
= VOCAL_STEMS //MK: The lyrics make no mention of the Unvoiced, and lean on the corporate conspiracy angle. Overall, the corp angle, if real, should affect Bass and Keys, too. I can do that.
+ [Encourage Mood Tattoos.]
#PlayMusic: vocals_whalesong_human
SINGER: musings on safety and collectivity, rather than the Unvoiced intent of people just not speaking, and them, not being sure about this stance at all.
-> VOCAL_STEMS
+ [Hate on Mood Tattoos.]
#PlayMusic: vocals_whalesong_whaleish
SINGER: musings on sticking it to the Unvoiced, highlighting the real implications, and talking directly to mom. Maybe baiting the Unvoiced into admitting they created the tattoos and own the company that makes them...
-> VOCAL_STEMS
+ [Come Get a Mood Tattoo.]
~ vocals_whalesong = "Human"
-> MOODTATTOOS_JAM
+ [Don't Get a Mood Tattoo.]
~ vocals_whalesong = "Whaleish"
-> MOODTATTOOS_JAM
= GUITAR_STEMS
+ [Play wistful riff.]
#PlayMusic: guitar_whalesong_human
GUITARIST: finds this one downbeat, like they miss something. Why can't they be upbeat about this? It's like an apology for something...
-> VOCAL_STEMS //MK: I guess this was in Whale Song, too. Shouldn't this direct back to THESE stems?
+ [Play moody riff.]
#PlayMusic: guitar_whalesong_whaleish
GUITARIST: musings on how this will create a warning and seriousness. They're serious, now. This is a real "keep your secrets" feel.
-> VOCAL_STEMS
+ [Choose wistful riff.]
~ guitar_whalesong = "Human"
-> MOODTATTOOS_JAM
+ [Choose moody riff.]
~ guitar_whalesong = "Whaleish"
-> MOODTATTOOS_JAM
= BASS_STEMS //MK: The Bass stem for Come Get... is almost non-existent for the first 30 seconds, so I'm referencing that part that's active. My worry is that the player may think something is wrong with the audio and stop listening. I did.
+ [Play stealthy Bass.]
#PlayMusic: bass_whalesong_human
BASSIST: musings on how this will pull people in and then surprise them.
-> VOCAL_STEMS
+ [Play insistent bass.]
#PlayMusic: bass_whalesong_whaleish
BASSIST: musings on how this sounds like something is chasing you, and the unease you should feel about getting a tattoo.
-> VOCAL_STEMS
+ [Choose stealthy bass.]
~ bass_whalesong = "Human"
-> MOODTATTOOS_JAM
+ [Choose insistent bass.]
~ bass_whalesong = "Whaleish"
-> MOODTATTOOS_JAM
= KEYS_STEMS
+ [Play aspirational keys.]
#PlayMusic: keys_whalesong_human
KEYS: musings on positivity and being part of something.
-> VOCAL_STEMS
+ [Play sneaky keys.]
#PlayMusic: keys_whalesong_whaleish
KEYS: musings on how this sounds sneaky and maybe you can't trust the tattoos. Or your own heart?! Oh, no!
-> VOCAL_STEMS
+ [Choose aspirational keys.]
~ keys_whalesong = "Human"
-> MOODTATTOOS_JAM
+ [Choose sneaky keys.]
~ keys_whalesong = "Whaleish"
-> MOODTATTOOS_JAM
=== MOODTATTOOS_JAM ===
#REJOIN
DRUMMER: ONE! EIGHT! FIVE!
GUITARIST: Is your personality program messing with your math?
DRUMMER: ... Let's just jam. //MK: can we keep the level 1/2/3 jokes the same in these places? This one was general for that reason. I can write six of them, but they should relate to the songs in that case. For this one, I'd have Akai remind everyone that while he can just grind off a paintjob he doesn't like, humans can only tattoo over something, so start thinking about what you'll do when you regret this tattoo...
#PlayMusic: {drums_whalesong}
#PlayMusic: {vocals_whalesong}
#PlayMusic: {guitar_whalesong}
#PlayMusic: {bass_whalesong}
#PlayMusic: {keys_whalesong}
//NOTE: I have to talk to JP about the above. I think this might trigger the music stems a split second apart, which will sound like crap. We might need a different command for this, but for now, you get the idea.
{song_stance_L1 == vocals_whalesong: //Check if stance the band chose and lyrics the singer chose are the same.
-> LYRICS_MATCH_STANCE
- else:
-> DISSENTER_SINGER
}
= LYRICS_MATCH_STANCE
{song_stance_L1 == "Whaleish":
-> DONT_GET_TATTOO //MK: didn't change these terms...
- else:
-> COME_GET_TATTOO
}
= DONT_GET_TATTOO
SINGER hopes this works. Corporate conspiracies are scary.
KEYBOARDIST asks SINGER why they hate these tattoos so much. Singer dodges the question...
BASSIST is pleased - there IS a conspiracy here. Good to expose it.
-> LOCKED_SONG
= COME_GET_TATTOO
SINGER offers a boarderline apology - this is the best they could do since they don't really believe it.
The others offer support, and KEYBOARDIST loves it.
BASS thinks it'll lure people in and then hilarity will ensue. GUITARIST makes it clear that they don't want to get a mood tattoo. Just so everyone knows.
-> LOCKED_SONG
//NOTE: Since everyone is in agreement, we don't need to give players a choice to change or "lock in" their musical choices. We can simply move on.
= DISSENTER_SINGER
{vocals_whalesong == "Whaleish":
KEYBOARDIST is stunned. Why would SINGER do this?
BASSIST is happy to call out corporate conspiracy, but this isn't what they agreed on.
GUITARIST wants to hear SINGER out. Mostly because they feel relieved.
- else:
What's this about? Is Singer trying to be ironic? KEYBOARDIST is sad - is SINGER making fun of THEM?
BASSIST doesn't know if the audience will get the 'joke'.
GUITARIST is angry - they have to suck it up and play, but Singer gets to go against the band?
}
SINGER knows they went rogue...
+ SINGER: I shouldn't have gone rogue like that.
+ SINGER: I thought I was making the right choice.
-
DRUMMER: So... you all good with your choices? Or are you changing things up?
#PlayerControlUntil: StemsLocked, JumpToPath: MOODTATTOOS_JAM.LOCKED_SONG
+ [BUTTONS POP UP - "Lock it in." or "Change it."]
-> CHANGE_STEMS
= CHANGE_STEMS
//NOTE: This won't be in split flow anymore, and the choices below are just for singleplayer Inky playthough purposes.
{
- char_singer:
-> SINGER_STEM_LOCK
- char_guitarist:
-> GUITARIST_STEM_LOCK
- char_bassist:
-> BASSIST_STEM_LOCK
- char_keyboardist:
-> KEYS_STEM_LOCK
}
= SINGER_STEM_LOCK
+ [Keep the lyrics.]
+ [Change them!]
++ [Don't Get a Mood Tattoo.]
~ vocals_whalesong = "Whaleish"
++ [Come Get a Mood Tattoo.]
~ vocals_whalesong = "Human"
--
-
-> LOCKED_SONG
= GUITARIST_STEM_LOCK
+ [Keep it.]
+ [Change it.]
++ [Wistful guitar.]
~ guitar_whalesong = "Human"
++ [Moody doom guitar.]
--
-
-> LOCKED_SONG
= BASSIST_STEM_LOCK
+ [Keep it.]
+ [Change it.]
++ [Stealthy bass to lure them in.]
~ bass_whalesong = "Whaleish"
++ [Insistent chase bass.]
~ bass_whalesong = "Human"
--
-
-> LOCKED_SONG
= KEYS_STEM_LOCK
+ [Keep it.]
+ [Change it!]
++ [Aspirational praise mood tattoos keys!]
~ keys_whalesong = "Whaleish"
++ [Sneaky conspiracy keys.]
~ keys_whalesong = "Human"
--
-
-> LOCKED_SONG
= LOCKED_SONG
SINGER wraps up the practice. Next stop: Read Only.
-> PERFORMANCE_WHALESONG

9
MAIN_Bandocracy.ink
View File

@ -3,15 +3,22 @@
INCLUDE Level1/OPENING.ink INCLUDE Level1/OPENING.ink
INCLUDE Level1/TIE_RULES.ink INCLUDE Level1/TIE_RULES.ink
INCLUDE Level1/SONG_TOPICS_L1.ink INCLUDE Level1/SONG_TOPICS_L1.ink
INCLUDE Level1/PRACTICE_WHALESONG.ink INCLUDE Level1/PRACTICE_WHALESONG.ink
INCLUDE Level1/PRACTICE_MOODTATTOOS.ink
INCLUDE Level1/PERFORMANCE_WHALESONG.ink INCLUDE Level1/PERFORMANCE_WHALESONG.ink
INCLUDE Level1/POST_PERFORM_WHALESONG.ink INCLUDE Level1/POST_PERFORM_WHALESONG.ink
INCLUDE Level1/OUTCOME_WHALESONG.ink INCLUDE Level1/OUTCOME_WHALESONG.ink
INCLUDE Level1/PRACTICE_MOODTATTOOS.ink
INCLUDE Level1/PERFORMANCE_MOODTATTOOS.ink
INCLUDE Level1/POST_PERFORM_MOODTATTOOS.ink
INCLUDE Level1/OUTCOME_MOODTATTOOS.ink
INCLUDE Level2/SONG_TOPICS_L2.ink INCLUDE Level2/SONG_TOPICS_L2.ink
// *** CHARACTER VARIABLES *** // *** CHARACTER VARIABLES ***
//ONBOARDING - for Single-Player mode; false unless selected //ONBOARDING - for Single-Player mode; false unless selected